標題: 求樣本值小於(大於)標準值涵數 [打印本頁]

---

作者: 074063    時間: 2015-10-28 21:57     標題: 求樣本值小於(大於)標準值涵數

本帖最後由 074063 於 2015-10-28 22:09 編輯

[attach]22261[/attach]

如附件,
標準範圍值在上下限在同一個儲存格(如B1格式)
求~ B2(樣本數):     B8以下有非空白儲存格個數合
        B3(低於標準): 樣本值內低於標準值(B1)個數合
        B4(高於標準): 樣本值內高於標準值(B1)個數合

勞煩各位大大不吝賜教 ^^

補充: 如附件B1格式, 如何取出 "~" 以左及以右的值? (B1的值位數不一定, 但上下限值中間一定有個"~")

---

作者: 准提部林    時間: 2015-10-29 10:10

本帖最後由 准提部林 於 2015-10-29 10:14 編輯

全部樣本個數：=COUNT(B7:B106)
低於標準個數．Ｂ３：=COUNTIF(B7:B106,"<"&LEFT(B1,FIND("~",B1)-1))
高於標準個數．Ｂ４：=COUNTIF(B7:B106,">"&MID(B1,FIND("~",B1)+1,9))

介於4.20~4.70個數：
=COUNTIF(B7:B106,">="&LEFT(B1,FIND("~",B1)-1))-COUNTIF(B7:B106,">"&MID(B1,FIND("~",B1)+1,9))
=SUM(COUNTIF(B7:B106,{">=",">"}&MID(SUBSTITUTE(B1,"~",REPT(0,50)),{1,25},50))*{1,-1})
=COUNT(B7:B106)-B3-B4

---

作者: yen956    時間: 2015-10-29 10:24

求~ B2(樣本數):     B8以下有非空白儲存格個數和
是否為:
求~ B2(樣本數):     B7以下有非空白儲存格個數和

試試看:
B2: =COUNTA($B$7B$65536)
B3: =COUNTIF($B$7B$65536,">="&LEFT($B$1,FIND("~",$B$1)-1))
B4: =COUNTIF($B$7B$65536,"<=" & RIGHT($B$1,LEN($B$1)-FIND("~",$B$1)))

---

作者: yen956    時間: 2015-10-29 11:12

本帖最後由 yen956 於 2015-10-29 11:15 編輯

更正：
B2: =COUNTA($B$7B$65536)
COUNTA會連文字等計算進去, COUNT 只計算數字儲存格
更正為 =COUNT($B$7B$65536)

B3: =COUNTIF($B$7B$65536,">="&LEFT($B$1,FIND("~",$B$1)-1))
更正為 =COUNTIF($B$7B$65536,">"&LEFT($B$1,FIND("~",$B$1)-1))
B4: =COUNTIF($B$7B$65536,"<=" & RIGHT($B$1,LEN($B$1)-FIND("~",$B$1)))
更正為 =COUNTIF($B$7B$65536,"<" & RIGHT($B$1,LEN($B$1)-FIND("~",$B$1)))

---

作者: 074063    時間: 2015-10-29 23:50

回復 2# 准提部林


    很實用~感謝 准提部林 大大解答 ^^

---

作者: 074063    時間: 2015-10-29 23:51

回復 4# yen956


    雖然算出來的個數不太正確~不過還是感謝 yen956 大大不吝賜教 ^^

---

作者: yen956    時間: 2015-10-30 14:31

回復 6# 074063
個數果然大大不正確, 謝謝指正!!(> 與 < 應對調才對)
正確如下:
B2:        =COUNT($B$7:$B$65536)
B3:        =COUNTIF($B$7:$B$65536,">"&LEFT($B$1,FIND("~",$B$1)-1))
B4:        =COUNTIF($B$7:$B$65536,"<" & RIGHT($B$1,LEN($B$1)-FIND("~",$B$1)))

---

歡迎光臨 麻辣家族討論版版 (http://forum.twbts.com/)