標題:
[發問]
找重複資料
[打印本頁]
作者:
ky2599y
時間:
2015-4-7 12:34
標題:
找重複資料
請問如下圖
台北市與基隆市都有大安區，要如何將有相同區域的縣市帶入D6~D12中
[attach]20593[/attach]
附件已上傳[attach]20594[/attach]
作者:
tku0216
時間:
2015-4-8 00:32
回復
1#
ky2599y
抱歉，學藝不精，目前只想到以下辦法：
先改變您的資料，將A15~B383兩欄資料對換，方便之後的公式查詢用，
之後在D6輸入公式"=VLOOKUP(C6,$A$16:$B$383,2,FALSE)&"、"&VLOOKUP(C6,OFFSET($A$16,MATCH(C6,$A$16:$A$383,0),0,ROWS($A$16:$A$383)-MATCH(C6,$A$16:$A$383,0),2),2,FALSE)"
大概意義如下：
1.前半段的公式用vlookup找到第一筆符合的資料。
2.後半段從前半段找到的資料開始，"往後位移"到最後一筆資料，組成新的查表陣列，並再一次使用vlookup查詢，以找到第二筆符合的資料。
這樣的方式必須假設只有兩筆符合的資料，若大於兩筆就不適用了。
補上附件：
[attach]20598[/attach]
作者:
p212
時間:
2015-4-8 10:12
本帖最後由 p212 於 2015-4-8 10:19 編輯
回復
1#
ky2599y
變通方式，請參考附件！
定義名稱
「縣市」，參照到輸入 =找重覆!$A$2:$A$369
「鄉鎮市區」，參照到輸入 =找重覆!$B$2:$B$369
「x」，參照到輸入 =IF(鄉鎮市區=找重覆!$E2,ROW(鄉鎮市區),"")
作者:
ky2599y
時間:
2015-4-8 11:14
回復
3#
p212
謝謝您的協助，在大安區中第2個欄顯示為彰化縣，但實際上應為台中市，我看好久想試著修改但卻有如丈二金剛^^
作者:
ky2599y
時間:
2015-4-8 11:17
回復
2#
tku0216
謝謝您的幫忙!但由於是考題~欄位不方便更動
但也給了我很好的提示，謝謝~
作者:
p212
時間:
2015-4-8 12:28
本帖最後由 p212 於 2015-4-8 12:34 編輯
回復
4#
ky2599y
因為定義名稱之「縣市」的參照範圍為 =找重覆!
$A$2
:$A$369
故3#附檔之儲存格F2應修正為
=IFERROR(INDEX(縣市,SMALL(x,COLUMN(A$1))
-1
),"")
向右向下複製公式
請參考！
作者:
samwang
時間:
2015-4-8 15:17
回復
1#
ky2599y
[attach]20603[/attach]
作者:
JBY
時間:
2015-4-8 16:35
請問如下圖
台北市與基隆市都有大安區，要如何將有相同區域的縣市帶入D6~D12中......
1] D6, 輸入陣列公式 (一齊按 Ctrl + Alt + Enter 3鍵 ) :
=INDEX(A$16:A$383,SMALL(IF(B$16:B$383=C6,ROW($1:$368)),1))&IFERROR("、"&INDEX(A$16:A$383,SMALL(IF(B$16:B$383=C6,ROW($1:$368)),2)),"")
向下複製公式
或者
2] D6, 輸入一般公式 :
=LOOKUP(2,1/(COUNTIF(OFFSET(B$16,,,ROW(A$1:A$368)),C6)*(B$16:B$383=C6)=1),A$16:A$383)&IFERROR("、"&LOOKUP(2,1/(COUNTIF(OFFSET(B$16,,,ROW(A$1:A$368)),C6)*(B$16:B$383=C6)=2),A$16:A$383),"")
向下複製公式
歡迎光臨 麻辣家族討論版版 (http://forum.twbts.com/)
