Board logo

標題: [發問] Vlookup求助 [打印本頁]
作者: takya    時間: 2015-3-9 22:42     標題: Vlookup求助

本帖最後由 takya 於 2015-3-9 22:43 編輯

本人新手, 想請教一下. 如想先以VLOOKUP尋找某一人, 但該人有多項成績, 想以日期前後來分第1次、第2次......成績, 函數應如何, 千萬的感謝!
作者: JBY    時間: 2015-3-10 08:48

H2 輸入陣列公式，左拉後下拉 :


{=INDEX($C:$C,MATCH(SMALL(IF($A:$A=$G2,$B:$B),COLUMN(A:A)),$B:$B,))}
作者: p212    時間: 2015-3-10 08:54

本帖最後由 p212 於 2015-3-10 08:58 編輯

回復 2# JBY
若於「相同日期」有「多人」情況下，則2#之公式不符期待。
請問如何修改？
謝謝！
作者: JBY    時間: 2015-3-10 14:06

本帖最後由 JBY 於 2015-3-10 14:09 編輯
回復  p212
若於「相同日期」有「多人」情況下，請問如何修改？



若有「相同日期」, 修改H2 陣列公式，輸入後左拉下拉 :

{=INDEX($C:$C,MATCH(SMALL(IF($A:$A=$G2,$B:$B),COLUMN(A:A)),IF($A:$A=$G2,$B:$B),))}
作者: p212    時間: 2015-3-10 15:55

本帖最後由 p212 於 2015-3-10 16:06 編輯

回復 4# JBY
没想到紅字部份可如此運用，製造MATCH的lookup_array。
=INDEX($C:$C,MATCH(SMALL(IF($A:$A=$G2,$B:$B),COLUMN(A:A)),IF($A:$A=$G2,$B:$B),))
感謝解惑！
註：隱蔽公式找不到的結果#NUM!，將之顯示為「空白」，陣列公式：
=IFERROR(INDEX($C:$C,MATCH(SMALL(IF($A:$A=$G2,$B:$B),COLUMN(A:A)),IF($A:$A=$G2,$B:$B),)),"")
請參考！
作者: JBY    時間: 2015-3-10 17:24

回復 5# p212

如果你對公式有興趣, 試試下面的陣列公式，我想你會有所發現的,

H2 陣列公式，輸入後左拉下拉 :

{=VLOOKUP($G2&SMALL(IF($A:$A=$G2,$B:$B),COLUMN(A:A)),IF({1,0},$A:$A&$B:$B,$C:$C),2,)}

{=AVERAGE(IF($A:$A=$G2,IF($B:$B=SMALL(IF($A:$A=$G2,$B:$B),COLUMN(A:A)),$C:$C)))}

{=SUMIFS($C:$C,$A:$A,$G2,$B:$B,SMALL(IF($A:$A=$G2,$B:$B),COLUMN(A:A)))}
作者: takya    時間: 2015-3-11 04:33

H2 輸入陣列公式，左拉後下拉 :


{=INDEX($CC,MATCH(SMALL(IF($AA=$G2,$BB),COLUMN(A:A)),$BB, ...
JBY 發表於 2015-3-10 08:48



感謝各位幫助.
但按照上述方式使用, 不知是否資料太多(約4千多筆資料), 回傳結果 #NUM!. 不知如何修正. 求賜教.
作者: k123456770    時間: 2015-3-18 16:00

如果人數不多的話
可以排序 時間 人名, 後 複製個人 成績, 選擇性貼上→轉置
會比Key公式快一些



歡迎光臨 麻辣家族討論版版 (http://forum.twbts.com/)