麻辣家族討論版版 - Powered by Discuz! Board

標題: [發問] 函數問題 [打印本頁]

作者: basarasy 時間: 2010-9-13 09:09 標題: 函數問題

在A1打 HGH5458 B1會出HGH C1出 5458
把英文和數字分開.
請問有什麼函數可以做到?

作者: oobird 時間: 2010-9-13 09:22

是否固定字節數？

作者: PD961A 時間: 2010-9-13 09:51

回復 1# basarasy

http://forum.twbts.com/viewthread.php?tid=1112&extra=page%3D5

作者: ANGELA 時間: 2010-9-13 10:05

格式都是字母3位數字4位,用資料剖析.

B1=LEFT(A1,MIN(FIND(ROW($1:$10)-1,A1&"1234567890"))-1) 陣列公式
C1=LOOKUP(9.9E+307,--RIGHT(A1,ROW($1:$20)))

作者: basarasy 時間: 2010-9-13 11:23

本帖最後由 basarasy 於 2010-9-13 11:24 編輯

回復 2# oobird

不固定字節數的.
EG.
GF6.. G90..JOUJJ9089

作者: ANGELA 時間: 2010-9-13 12:02

B1=SUM(MID(A1,LARGE(IF(ISNUMBER(--MID(A1,ROW($1:$99),1)),ROW($1:$99)),ROW(INDIRECT("1:"&COUNT(--MID(A1,ROW($1:$99),1))))),1)*10^ROW(INDIRECT("1:"&COUNT(--MID(A1,ROW($1:$99),1))))/10) 陣列公式

作者: basarasy 時間: 2010-9-13 13:44

本帖最後由 basarasy 於 2010-9-13 13:45 編輯

回復 4# ANGELA

謝謝ANGELA大大^^
為什麼
B1=LEFT(A1,MIN(FIND(ROW($1

10)-1,A1&"1234567890"))-1) 陣列公式
C1=LOOKUP(9.9E+307,--RIGHT(A1,ROW($1

20)))

row要 1:10 ? 1:20?
可以 1:1嗎?

作者: oobird 時間: 2010-9-13 14:28

b1=LEFT(A1,LEN(A1)-(SUM(LEN(A1)-LEN(SUBSTITUTE(A1,{"0","1","2","3","4","5","6","7","8","9"," "},"")))))
c1=SUBSTITUTE(A1,B1,"")
普通公式

作者: basarasy 時間: 2010-9-13 19:37

回復 8# oobird

謝謝超級版主^^
有普通公式真好><

作者: leiru 時間: 2010-9-13 23:48

請教oobird 版主,不了解 b1公式的意思.可否解釋一次.謝謝...
另外,為何是用{"0","1","2","3","4","5","6","7","8","9"," "}

作者: asimov 時間: 2010-9-14 00:57

另一個陣列公式
b1=LEFT(A1,LEN(A1)-SUM(ISNUMBER(--RIGHT(A1,ROW($1:$100)))*1))

作者: asimov 時間: 2010-9-14 01:05

格式都是字母3位數字4位,用資料剖析.

B1=LEFT(A1,MIN(FIND(ROW($110)-1,A1&"1234567890"))-1) 陣列公式 ...
ANGELA 發表於 2010-9-13 10:05

ANGELA 使用find函數讓人耳目一新
巧妙運用"1234567890"避免產生錯誤
是不錯的解法

作者: oobird 時間: 2010-9-14 07:55

就是把所有看似數字的字符及空格都消除後剩下的就是字母了。

作者: ANGELA 時間: 2010-9-14 10:43

=LEFT(A1,LEN(A1)-(SUM(LEN(A1)-LEN(SUBSTITUTE(A1,{"0","1","2","3","4","5","6","7","8","9"," "},"")))))
從A1的左邊取A!總長度減去所有找到0~9及空白的數量的位數.
6F是陣列公式可找到任何不規則的數字.

作者: joviwang 時間: 2010-9-16 11:16

b1=MID(A1,1,FIND({"1","2","3","4","5","6","7","8","9","0"},A1)-1)
c1=MID(A1,FIND({"1","2","3","4","5","6","7","8","9","0"},A1),99)

作者: joviwang 時間: 2010-9-16 13:43

對不起，上一帖只能找到1而已，
不是個正確的解法，請刪除。

作者: kaigan89 時間: 2010-9-18 10:16

如果固定字節是不是就可以用資料剖析來完成！

歡迎光臨麻辣家族討論版版 (http://forum.twbts.com/)