Board logo

標題: [發問] 如何統計篩選的總和 [打印本頁]
作者: cbl0924    時間: 2014-12-22 20:26     標題: 如何統計篩選的總和

如何在這寫上公式
統計 基本資料裡的
台東縣 而且是士林區的人數總和
(不管1區或2區都加在一起)

依此類推.
[attach]19898[/attach]
[attach]19899[/attach]
[attach]19900[/attach]
作者: owen06    時間: 2014-12-22 22:59

回復 1# cbl0924


    b2=SUMPRODUCT((基本資料!$A$2:$A$54=$A2)*(LEFT(基本資料!$C$2:$C$54,2)=B$1)*基本資料!$B$2:$B$54)

   向右、向下拉複製。
作者: cbl0924    時間: 2014-12-23 08:29

回復 2# owen06


    請問在那基本資料裡的範圍不能是整條的A欄位嗎 ？ （B欄與C欄也一樣）
因為資料會增加或減少啊
作者: p212    時間: 2014-12-23 09:00

本帖最後由 p212 於 2014-12-23 09:03 編輯

回復 3# cbl0924
資料會增減時可考慮使用「動態範圍」處理
1.定義名稱
(1)「縣市」，參照到輸入=OFFSET(基本資料!$A$2,,,COUNTA(基本資料!$A:$A)-1)
(2)「人數」，參照到輸入=OFFSET(基本資料!$B$2,,,COUNTA(基本資料!$B:$B)-1)
(3)「區別」，參照到輸入=OFFSET(基本資料!$C$2,,,COUNTA(基本資料!$C:$C)-1)
2.「篩選統計」工作表之儲存格B2輸入
=SUMPRODUCT((縣市=$A2)*(LEFT(區別,2)=B$1)*人數)
向右、向下複製公式
請參考！
作者: cbl0924    時間: 2014-12-23 09:56

回復 4# p212


    如果已上面owen 的公式 是篩選統計單一個區沒問題

以owen的公式來說
如果我要將大同跟 中正 加在同一個儲存格
我在left 前面加 or 怎麼就算不出來
是我or 加錯了？？
作者: owen06    時間: 2014-12-23 10:14

本帖最後由 owen06 於 2014-12-23 10:17 編輯

回復 5# cbl0924


   =SUMPRODUCT((基本資料!$A$2:$A$54=$A4)*((LEFT(基本資料!$C$2:$C$54,2)="大同")+(LEFT(基本資料!$C$2:$C$54,2)="中正"))*基本資料!$B$2:$B$54)

  在同欄位有多條件的話，基本上的語法是這樣，你再自行應用改成你要的方式即可。
作者: cbl0924    時間: 2014-12-23 10:30

回復 6# owen06


    明白  多謝  多謝

加總是沒問題了
如果要計次呢？
如台東縣 士林x區 有174人  沒問題了
有3行
這個3 該怎麼寫出來呢？
作者: p212    時間: 2014-12-23 10:46

本帖最後由 p212 於 2014-12-23 10:48 編輯

回復 7# cbl0924
承4#
「篩選統計」工作表之儲存格B2公式修改為
=SUMPRODUCT((縣市=$A2)*(LEFT(區別,2)=B$1))
向右、向下複製公式
請參考！
作者: owen06    時間: 2014-12-23 10:57

回復 7# cbl0924

    你是要算出台東的士林X區共出現幾個嗎？如果是的話
    =SUMPRODUCT((基本資料!$A$2:$A$54="台東")*(LEFT(基本資料!$C$2:$C$54,2)="士林"))
    概念是這樣，你再將"台東"、"士林"改成自己表格對應的儲存格即可。
作者: cbl0924    時間: 2014-12-23 11:13

回復 9# owen06


    完成
謝謝兩位的教導

請問公式裡的*意思是 ？
作者: p212    時間: 2014-12-23 16:15

回復 10# cbl0924
「*」=「and」
「+」=「or」
請參考
作者: rouber590324    時間: 2014-12-23 16:53

* = *前後條件要同時成立
作者: Ling2050    時間: 2014-12-24 16:17

回復 10# cbl0924


        * 公式是相乘的意思,感覺像是集合論的交集...
作者: p212    時間: 2014-12-26 08:36

本帖最後由 p212 於 2014-12-26 08:44 編輯

回復 13# Ling2050
11#補充說明
在8#之 =SUMPRODUCT((縣市=$A2)*(LEFT(區別,2)=B$1))
公式中的運算子「*」執行AND運算   (若為運算子「+」，則執行OR運算。)
請參考！
作者: tku0216    時間: 2014-12-29 18:19

回復 1# cbl0924

提供另外一個方法，於B2儲存格鑑入
=SUMIFS(基本資料!$B$2:$B$54,基本資料!$A$2:$A$54,$A2,基本資料!$C$2:$C$54,B$1&"*")，一樣可以求得答案。(記得向下、向右複製公式)



歡迎光臨 麻辣家族討論版版 (http://forum.twbts.com/)