麻辣家族討論版版 - Powered by Discuz! Board

標題: 請教各位前輩統計的問題 [打印本頁]

作者: ryan36241 時間: 2014-10-15 16:27 標題: 請教各位前輩統計的問題

如果要設計一個統計的表格，想要在指定的儲存格內輸入日期就會直接帶出相關資料
這樣該如何製作？
格式如下表：

[attach]19347[/attach]

作者: ML089 時間: 2014-10-15 18:12

回復 1# ryan36241

J4 =SUMPRODUCT(($D$3:$D$14=RIGHT($H4))*($B$3:$B$14=$H$2))
L4 =SUMPRODUCT(($D$3:$D$14=RIGHT($H4))*($B$3:$B$14=$H$2),$E$3:$E$14)

作者: ryan36241 時間: 2014-10-15 21:33

回復 ryan36241

J4 =SUMPRODUCT(($D$3D$14=RIGHT($H4))*($B$3B$14=$H$2))
L4 =SUMPRODUCT(($D$ ...
ML089 發表於 2014-10-15 18:12

謝謝前輩指教，這樣可以正確導出我要的值
但想順便請教一下，如果類別的筆數部份想要以序號區分該怎麼作？
例如：Ａ的類別在15號有三筆　但其中兩筆序號相同　一筆不同故系統會判別只有兩筆

作者: ML089 時間: 2014-10-15 22:54

回復 3# ryan36241

請再模擬檔案傳上來看看

作者: ryan36241 時間: 2014-10-16 12:49

回復 ryan36241

請再模擬檔案傳上來看看
ML089 發表於 2014-10-15 22:54

檔案如下附件，有將需求寫在表格內
再麻煩前輩指教了～　謝謝

[attach]19350[/attach]

作者: samwang 時間: 2014-10-16 15:28

回復 5# ryan36241

L3=SUMPRODUCT(($D$2:$D$7=$K3)*($B$2:$B$7=$K$1))
M3=SUMPRODUCT(($D$2:$D$7=$K3)*($B$2:$B$7=$K$1),$E$2:$E$7)

作者: ML089 時間: 2014-10-16 16:03

回復 5# ryan36241

L3 =SUMPRODUCT((B$2:B$9=K$1)*(D$2:D$9=K3)*(MATCH(C$2:C$9&D$2:D$9,C$1:C$9&D$1:D$9,)=ROW($2:$9)))
M3 =SUMPRODUCT((B$2:B$9=K$1)*(D$2:D$9=K3),E$2:E$9)

[attach]19352[/attach]

作者: ryan36241 時間: 2014-10-16 19:03

回復 ryan36241

L3 =SUMPRODUCT((B$2:B$9=K$1)*(D$2$9=K3)*(MATCH(C$2:C$9&D$2$9,C$1:C$9&D$1$9 ...
ML089 發表於 2014-10-16 16:03

感謝前輩幫忙~~~ 終於把報表製作好了
謝謝呦~~
順便請問一下，如果要指定一直列的儲存格
B$2:B$9要指定為Ｂ直列的話該如何寫？

作者: ryan36241 時間: 2014-10-16 19:09

感謝前輩幫忙~~~ 終於把報表製作好了
謝謝呦~~
順便請問一下，如果要指定一直列的儲存格
B$2:B$9 ...
ryan36241 發表於 2014-10-16 19:03

還有如果要設計整個月份的統計要如何寫?
再麻煩前輩指教~
謝謝

作者: ML089 時間: 2014-10-16 22:10

回復 8# ryan36241

L3 =SUMPRODUCT((B$2:B$9=K$1)*(D$2:D$9=K3)*(MATCH(C$2:C$9&D$2:D$9,C$1:C$9&D$1:D$9,)=ROW($2:$9)))
M3 =SUMPRODUCT((B$2:B$9=K$1)*(D$2:D$9=K3),E$2:E$9)

修改此判斷式 (B$2:B$9=K$1)
改為 (MONTH(B$2:B$9)=K$1)
K$1輸入 1~12 (月份)

作者: samwang 時間: 2014-10-17 11:48

回復 9# ryan36241

僅供參考
月份 L3=SUMPRODUCT(1/COUNTIF($C$2:$C$7,$C$2:$C$7)*(MONTH(B$2:B$7)=K$1)*(D$2:D$7=$K3))
日期 L3=SUMPRODUCT(1/COUNTIF($C$2:$C$7,$C$2:$C$7)*(B$2:B$7=K$1)*(D$2:D$7=$K3))

以下是陣列公式
月份 L3=COUNT(1/(MATCH(C$2:C$7,IF(MONTH($B$2:$B$7)&$D$2:$D$7=K$1&$K3,C$2:C$7),)=ROW($1:$7)))
日期 L3=COUNT(1/(MATCH(C$2:C$7,IF($B$2:$B$17&$D$2:$D$7=K$1&$K3,C$2:C$7),)=ROW($1:$7)))

歡迎光臨麻辣家族討論版版 (http://forum.twbts.com/)