Board logo

標題: 公式沒問題，答案有問題 ?? [打印本頁]
作者: t8899    時間: 2014-10-14 19:37     標題: 公式沒問題，答案有問題 ??

公式沒問題，答案有問題 ??[attach]19343[/attach]
作者: ML089    時間: 2014-10-15 17:09

回復 1# t8899

以金額或數量作為MATCH查詢時，當出現多筆相同金額時，只能找到第一筆資料位置，所以會重複

LARGE是很耗計算的函數，可用多筆儲存格陣列公式可以加速計算

R2:U2 多筆儲存格陣列公式
=IF(ROW(A1)>COUNT($Y$2:$Y$900),"",INDIRECT({"W","V","X","Y"}&ROUND(1/MOD(LARGE((0&$Y$2:$Y$900)+1/ROW($2:$900),ROW(A1)),1),0)))

選R2:U2 下拉複製
作者: t8899    時間: 2014-10-15 19:49

回復  t8899

以金額或數量作為MATCH查詢時，當出現多筆相同金額時，只能找到第一筆資料位置，所以會重複 ...
ML089 發表於 2014-10-15 17:09


謝謝指導
作者: samwang    時間: 2014-10-16 12:09

回復 1# t8899

R2陣列公式，往右往下拉 (R和S欄的資料和原先欄位對調)，另一種僅供參考
=IFERROR(OFFSET(INDIRECT("V"&SMALL(IF(LARGE($Y$2:$Y$900,ROW()-1)=$Y$2:$Y$900,ROW($2:$900)),COUNTIF($AF$2:$AF2,$AF2))),0,COLUMN(A1)-1),"")
作者: t8899    時間: 2014-10-16 12:15

回復  t8899

R2陣列公式，往右往下拉 (R和S欄的資料和原先欄位對調)，另一種僅供參考
=IFERROR(OFFSE ...
samwang 發表於 2014-10-16 12:09


謝謝指導
作者: t8899    時間: 2014-10-16 18:09

回復  t8899

以金額或數量作為MATCH查詢時，當出現多筆相同金額時，只能找到第一筆資料位置，所以會重複 ...
ML089 發表於 2014-10-15 17:09

請問S,T,U三欄的公式是什麼呢?
作者: t8899    時間: 2014-10-16 18:34

本帖最後由 t8899 於 2014-10-16 18:43 編輯
回復  t8899

以金額或數量作為MATCH查詢時，當出現多筆相同金額時，只能找到第一筆資料位置，所以會重複 ...
ML089 發表於 2014-10-15 17:09

找到了,是這四個 ==> INDIRECT({"w","v","X","Y"}
顯示是第一個W , V,X,Y 的順序有差嗎???
你的公式我把它擺在最右邊，少了一個華經沒抓到 ???[attach]19353[/attach][attach]19353[/attach]
作者: ML089    時間: 2014-10-16 21:51

回復 7# t8899


AC2
=IF(ROW(A1)>COUNT($K2:$L900),"",INDIRECT({"L","J","K","I"}&ROUND(1/MOD(LARGE((0&$K$2:$K$900)+1/ROW($2:$900),ROW(A1)),1),0)))
你修改的公式 COUNT($K2:$L900) 中 2及900都應該鎖住，改為 COUNT($K＄2:$L＄900)
作者: ML089    時間: 2014-10-16 22:02

本帖最後由 ML089 於 2014-10-16 22:04 編輯
請問S,T,U三欄的公式是什麼呢?
t8899 發表於 2014-10-16 18:09



6#
請問S,T,U三欄的公式是什麼呢?

7#
找到了,是這四個 ==> INDIRECT({"w","v","X","Y"}
顯示是第一個W , V,X,Y 的順序有差嗎???

前面以經說明公式為多筆儲存格陣列公式，公式一次回傳4個值 已經包含 S,T,U

7#樓的檔案公式如下

AC2:AF2(多筆儲存格陣列公式)
=IF(ROW(A1)>COUNT($K$2:$L$900),"",INDIRECT({"L","I","J","K"}&ROUND(1/MOD(LARGE((0&$K$2:$K$900)+1/ROW($2:$900),ROW(A1)),1),0)))

AG2:AJ2(多筆儲存格陣列公式)
=IF(ROW(A1)>COUNT($Y$2:$Y$900),"",INDIRECT({"W","V","X","Y"}&ROUND(1/MOD(LARGE((0&$Y$2:$Y$900)+1/ROW($2:$900),ROW(A1)),1),0)))


上2式亦可改為單筆陣列公式

AC2 =IF(ROW(A1)>COUNT($K$2:$L$900),"",INDIRECT("L"&ROUND(1/MOD(LARGE((0&$K$2:$K$900)+1/ROW($2:$900),ROW(A1)),1),0)))
AD2 =IF(ROW(A1)>COUNT($K$2:$L$900),"",INDIRECT("I"&ROUND(1/MOD(LARGE((0&$K$2:$K$900)+1/ROW($2:$900),ROW(A1)),1),0)))
AE2 =IF(ROW(A1)>COUNT($K$2:$L$900),"",INDIRECT("J"&ROUND(1/MOD(LARGE((0&$K$2:$K$900)+1/ROW($2:$900),ROW(A1)),1),0)))
AF2 =IF(ROW(A1)>COUNT($K$2:$L$900),"",INDIRECT("K"&ROUND(1/MOD(LARGE((0&$K$2:$K$900)+1/ROW($2:$900),ROW(A1)),1),0)))

AG2 =IF(ROW(A1)>COUNT($Y$2:$Y$900),"",INDIRECT("W"&ROUND(1/MOD(LARGE((0&$Y$2:$Y$900)+1/ROW($2:$900),ROW(A1)),1),0)))
AH2 =IF(ROW(A1)>COUNT($Y$2:$Y$900),"",INDIRECT("V"&ROUND(1/MOD(LARGE((0&$Y$2:$Y$900)+1/ROW($2:$900),ROW(A1)),1),0)))
AI2 =IF(ROW(A1)>COUNT($Y$2:$Y$900),"",INDIRECT("X"&ROUND(1/MOD(LARGE((0&$Y$2:$Y$900)+1/ROW($2:$900),ROW(A1)),1),0)))
AJ2 =IF(ROW(A1)>COUNT($Y$2:$Y$900),"",INDIRECT("Y"&ROUND(1/MOD(LARGE((0&$Y$2:$Y$900)+1/ROW($2:$900),ROW(A1)),1),0)))
作者: t8899    時間: 2014-10-17 12:12

6#
請問S,T,U三欄的公式是什麼呢?

7#
找到了,是這四個 ==> INDIRECT({"w","v","X","Y"}
顯示是 ...
ML089 發表於 2014-10-16 22:02


謝謝指導
作者: ML089    時間: 2014-10-17 14:59

回復 10# t8899

9# 測試檔案請參考

[attach]19354[/attach]
作者: t8899    時間: 2014-10-17 15:03

回復  t8899

9# 測試檔案請參考
ML089 發表於 2014-10-17 14:59


都正確，謝謝
用你的速度比較快??



歡迎光臨 麻辣家族討論版版 (http://forum.twbts.com/)