標題:
[發問]
從某資料夾中，將檔案名稱建立在excel中
[打印本頁]
作者:
hugh0620
時間:
2014-9-29 21:43
標題:
從某資料夾中，將檔案名稱建立在excel中
Dear 大大
有無辦法將某個資料夾中的影音檔(副檔名:.wmv或任何副檔名)名稱，
1.每一個影音檔的名稱都建立在excel中
(如果可以，是否一個欄位寫檔案名稱、一個欄位寫上副檔名稱[ex：excel 就填上excel、word就填上word])
2.每個名稱建立超連結
[attach]19255[/attach]
作者:
hugh0620
時間:
2014-9-30 13:42
本帖最後由 hugh0620 於 2014-9-30 13:45 編輯
Dear 大大
附件是我初稿，有設定類似指定資料夾，在抓取該資料夾中的檔案名稱，但發生了問題
[attach]19258[/attach]
下面是我的程式碼
在第13列 myFileName = Dir(myPath, 0) 抓到的是""，所以，跑不出來
Option Explicit
Private Sub CommandButton1_Click()
Dim myPath As String
Dim myFileName As String
Dim i As Long
Dim K As Integer
With Application.FileDialog(msoFileDialogFolderPicker)
.Show
If .ButtonName = "確定" Then
myPath = .SelectedItems(1)
myFileName = Dir(myPath, 0)
Do While Len(myFileName) > 0
Debug.Print myPath & myFileName
sheet1.Range("B65536").End(xlUp).Offset(1, 0) = myPath '路徑
sheet1.Range("C65536").End(xlUp).Offset(1, 0) = myFileName '檔名
K = K + 1
sheet1.Range("A65536").End(xlUp).Offset(1, 0) = K 'No
myFileName = Dir()
Loop
End If
End With
End Sub
複製代碼
作者:
GBKEE
時間:
2014-10-1 10:59
回復
2#
hugh0620
試試看
Option Explicit
Private Sub CommandButton1_Click()
Dim myPath As String
Dim K As Integer
Dim F As Object, E As Object
With Application.FileDialog(msoFileDialogFolderPicker)
'If .ButtonName = "確定" Then
'**不管你是否按下確定鍵,或是關閉對話視窗, ** 這行程式碼都是正確的 ***'
If .Show = True Then '有按下確定鍵
myPath = .SelectedItems(1)
Set F = CreateObject("Scripting.FileSystemObject").GetFolder(myPath).Files
'FileSystemObject 物件 有提供檔案內容的屬性可用
If F.Count > 0 Then
Cells.Clear
K = 5
Cells(K, "a") = "No"
Cells(K, "b") = "路徑"
Cells(K, "c") = "音檔案名稱"
Cells(K, "d") = "檔案大小"
Cells(K, "E") = "檔案型態"
For Each E In F
If E.Type = "MP3 格式聲音" Then '指定你的檔案型態: "影音檔"
K = K + 1
Cells(K, "a") = K - 5
Cells(K, "b") = myPath
Cells(K, "c") = E.Name
Cells(K, "d") = Format(E.Size / 1024, "#,000 KB")
Cells(K, "E") = E.Type
End If
Next
End If
End If
End With
End Sub
複製代碼
歡迎光臨 麻辣家族討論版版 (http://forum.twbts.com/)
