標題: 請問大大,如果要把國字轉成數字要用那一個函數呢?? [打印本頁]

---

作者: gctsai    時間: 2014-9-21 21:38     標題: 請問大大,如果要把國字轉成數字要用那一個函數呢??

請問各位大大:
如果要把壹零叁年捌月貳拾日轉成103812要用那一個函數呢??

---

作者: ML089    時間: 2014-9-22 09:18

回復 1# gctsai

沒有這種函數可以直接轉換
你需要將 年、月、日 國字型數字表達方式仔細說明

你提供的 "壹零叁年捌月貳拾日" 所提供的轉換格式並非是一致性

壹零叁年  是屬於 "[DBNum2][$-404]0" 這種格式
貳拾日 是屬於 "[DBNum2][$-404][DBNum2][$-404]G/通用格式" 這種格式

你是否先歸納一下或提供更多要轉換的資料才能研判如何處理

數字轉國字樣式參考
        [DBNum2][$-404]G/通用格式        [DBNum2][$-404]0
數字        轉換1        轉換2
1        壹        壹
2        貳        貳
3        參        參
4        肆        肆
5        伍        伍
6        陸        陸
7        柒        柒
8        捌        捌
9        玖        玖
10        壹拾        壹零
11        壹拾壹        壹壹
12        壹拾貳        壹貳
13        壹拾參        壹參
14        壹拾肆        壹肆
15        壹拾伍        壹伍
16        壹拾陸        壹陸
17        壹拾柒        壹柒
18        壹拾捌        壹捌
19        壹拾玖        壹玖
20        貳拾        貳零
21        貳拾壹        貳壹
22        貳拾貳        貳貳
101        壹佰零壹        壹零壹
102        壹佰零貳        壹零貳
103        壹佰零參        壹零參
104        壹佰零肆        壹零肆
105        壹佰零伍        壹零伍

---

作者: rouber590324    時間: 2014-9-22 09:40

如下
1.儲存格 A1 = 壹零叁年捌月貳拾日
    儲存格 B1 輸入   
=SUBSTITUTE(SUBSTITUTE(SUBSTITUTE(SUBSTITUTE(SUBSTITUTE(SUBSTITUTE(A1,"壹",1),"貳",2),"叁",3),"肆",4),"伍",5),"陸",6)
   儲存格 B2 輸入如下 . B2即秀出需求之103820
   =SUBSTITUTE(SUBSTITUTE(SUBSTITUTE(SUBSTITUTE(SUBSTITUTE(SUBSTITUTE(SUBSTITUTE(SUBSTITUTE(B1,"柒",7),"捌",8),"玖",9),"零",0),"拾",0),"年",""),"月",""),"日","")

---

作者: ML089    時間: 2014-9-25 20:32

回復 3# rouber590324

你的公式執行 "壹零叁年捌月貳拾壹日"  會得  "1038201" ，貳拾壹 變成 201 是不對的。

---

作者: ML089    時間: 2014-9-25 21:47

1.儲存格 A1 = "壹零叁年捌月貳拾日"
2.儲存格 B1 輸入公式
=LOOKUP(1,-FIND(TEXT(ROW($99:$111),"[DBNum2][$-404]0")&"年",A1),ROW($99:$111))
&-LOOKUP(1,-FIND(RIGHT(TEXT(ROW($1:$12),"[DBNum2][$-404]G/通用格式"),ROW($10:$21)/10)&"月",A1),ROW($1:$12))
&-LOOKUP(1,-FIND(RIGHT(TEXT(ROW($1:$31),"[DBNum2][$-404]G/通用格式"),ROW($10:$40)/10)&"日",A1),ROW($1:$31))

---

歡迎光臨 麻辣家族討論版版 (http://forum.twbts.com/)