標題: 跨表依符合條件篩選. [打印本頁]

---

作者: leiru    時間: 2014-7-17 15:53     標題: 跨表依符合條件篩選.

"篩選"工作表，若在B2輸入10305，希望A：H欄去抓"統計"工作表內符合B2的A：H欄，並在最後一欄顯示合計

---

作者: p212    時間: 2014-7-18 12:00

本帖最後由 p212 於 2014-7-18 12:06 編輯

回復 1# leiru
「篩選」工作表儲存格A4輸入陣列公式
for Excel 2007
=IFERROR(INDEX(統計!A$2:A$61,SMALL(IF(--LEFT(統計!$A$2:$A$61,5)=$B$1,ROW(統計!$A$2:$A$61)-1,4^8),ROW(1:1))),"")
for Excel 2003
=IF(ISERROR(SMALL(IF(--LEFT(統計!$A$2:$A$61,5)=$B$1,ROW(統計!$A$2:$A$61)-1,4^8),ROW(1:1))),"",INDEX(統計!A$2:A$61,SMALL(IF(--LEFT(統計!$A$2:$A$61,5)=$B$1,ROW(統計!$A$2:$A$61)-1,4^8),ROW(1:1))))
向右向下複製
請參考！
註：依範例提供「篩選」工作表其輸入指定值於儲存格B1，而非儲存格B2。

---

作者: leiru    時間: 2014-7-18 14:57

回復 2# p212


    謝謝回覆，另外有提到，符合條件的資料最後一列a欄內顯示＂合計＂並在G欄內把全部數字相加起來。
謝謝

---

作者: p212    時間: 2014-7-18 17:15

本帖最後由 p212 於 2014-7-18 17:17 編輯

回復 3# leiru
「篩選」工作表之儲存格G4修改成 陣列公式
=IF((A4="")*(A3=""),"",IF((A4="")*(A3<>""),"合計："&SUM($G$3:G3),INDEX(統計!G$2:G$61,SMALL(IF(--LEFT(統計!$A$2:$A$61,5)=$B$1,ROW(統計!$A$2:$A$61)-1,4^8),ROW(1:1)))))
向下複製
請參考！

---

作者: leiru    時間: 2014-7-18 17:37

回復 4# p212


    謝謝您
另，再請問，合計那儲存格如何將數值設定千分位。

---

作者: p212    時間: 2014-7-18 18:18

本帖最後由 p212 於 2014-7-18 18:22 編輯

回復 5# leiru
欲將「篩選」工作表之儲存格G4的數值設定「千分位」，請修改成陣列公式：
=IF((A4="")*(A3=""),"",IF((A4="")*(A3<>""),"合計："&TEXT(SUM($G$3:G3),"#,000"),INDEX(統計!G$2:G$61,SMALL(IF(--LEFT(統計!$A$2:$A$61,5)=$B$1,ROW(統計!$A$2:$A$61)-1,4^8),ROW(1:1)))))
請參考！

---

作者: leiru    時間: 2014-7-21 10:51

再請問：
統計工作表內的L2及L3如何求出值。（依A欄求出來的）

---

作者: p212    時間: 2014-7-21 11:59

本帖最後由 p212 於 2014-7-21 12:07 編輯

回復 7# leiru
統計工作表儲存格L2輸入陣列公式
for Excel 2007
=IFERROR(INDEX(統計!A$2:A$61,LARGE(IF(--LEFT(統計!$B$2:$B$61,5)=$K2,ROW(統計!$B$2:$B$61)-1,FALSE),1)),"")
for Excel 2003
=IF(ISERROR(LARGE(IF(--LEFT(統計!$B$2:$B$61,5)=$K2,ROW(統計!$B$2:$B$61)-1,FALSE),1)),"",INDEX(統計!A$2:A$61,LARGE(IF(--LEFT(統計!$B$2:$B$61,5)=$K2,ROW(統計!$B$2:$B$61)-1,FALSE),1)))
向下複製
請參考！

---

作者: leiru    時間: 2014-7-21 13:02

回復 8# p212


    謝謝您的回答....:)

---

作者: leiru    時間: 2014-7-21 15:59

回復 8# p212


    不好意思，再請教，篩選工作表內的L2儲存格是否可動態的依統計工作表內的B欄做下拉式選單，因統計工作表內的B欄會再繼續一直新增日期下去。

感謝您熱心回覆

---

作者: p212    時間: 2014-7-21 16:32

本帖最後由 p212 於 2014-7-21 16:45 編輯

回復 10# leiru
附檔內公式為Excel 2007版以上適用，請參考！

---

作者: leiru    時間: 2014-7-21 18:00

回復 11# p212

大師：
不好意思，一直向您請教，這次的問題：
因統計工作表內的B欄會再繼續一直新增日期下去，篩選工作表內的L2儲存格是否可動態的依統計工作表內的B欄做下拉式選單。

---

作者: p212    時間: 2014-7-22 08:27

本帖最後由 p212 於 2014-7-22 08:28 編輯

回復 12# leiru
12#問(篩選工作表內的L2儲存格是否可動態的依統計工作表內的B欄做下拉式選單。)看來有點奇怪！
您的需求是要在「篩選」工作表內的「B1儲存格」建立動態選單？

---

作者: p212    時間: 2014-7-22 09:22

回復 12# leiru
請參考！

---

作者: leiru    時間: 2014-7-22 09:36

回復 14# p212


  謝謝您提供的答案，我所要的就是您這檔案的答案。非常感謝您
不好意思，一直麻煩您了。:)

---

歡迎光臨 麻辣家族討論版版 (http://forum.twbts.com/)