麻辣家族討論版版 - Powered by Discuz! Board

標題: [發問] 排序的問題~ [打印本頁]

作者: ms2001 時間: 2014-7-10 00:32 標題: 排序的問題~

[attach]18667[/attach][attach]18668[/attach]
我想在工作表2中取得工作表1中的資料，並排序大小，當我在工作表2的a2裡打上人員號碼，
下面就會依金額的大到小排序出相同人員單據編號跟金額(如圖)，單據編號不重復，人員號碼
會重復，金額也會重復，有高手可以幫忙嗎?

作者: p212 時間: 2014-7-10 08:32

本帖最後由 p212 於 2014-7-10 08:35 編輯

回復 1# ms2001
1、圈選工作表1之A1:C14，按Ctrl+Shift+F3，以「頂端列」為名稱。
2、for Excel 2007
工作表2之儲存格A4輸入陣列公式 (以Ctrl+Shift+Enter輸入)
=IFERROR(INDEX(單據編號,SMALL(IF(人員編號=$A$2,ROW(人員編號),FALSE),ROW(1:1))-1),"")
儲存格B4輸入陣列公式
=IFERROR(INDEX(金額,SMALL(IF(人員編號=$A$2,ROW(人員編號),FALSE),ROW(1:1))-1),"")
for Excel 2003
工作表2之儲存格A4輸入陣列公式 (以Ctrl+Shift+Enter輸入)
=IF(ISERROR(SMALL(IF(人員編號=$A$2,ROW(人員編號),FALSE),ROW(1:1))),"",INDEX(單據編號,SMALL(IF(人員編號=$A$2,ROW(人員編號),FALSE),ROW(1:1))-1))
儲存格B4輸入陣列公式
=IF(ISERROR(SMALL(IF(人員編號=$A$2,ROW(人員編號),FALSE),ROW(1:1))),"",INDEX(金額,SMALL(IF(人員編號=$A$2,ROW(人員編號),FALSE),ROW(1:1))-1))
向下複製公式
請參考！

作者: ms2001 時間: 2014-7-10 23:20

試了一下，資料會出來，可是並不會排序，請問p大是有哪裡該修正嗎?

作者: jenny1203 時間: 2014-7-21 14:28

請問哪裡可以查到ISEFFOR, IF用法?

作者: p212 時間: 2014-7-21 14:59

本帖最後由 p212 於 2014-7-21 15:00 編輯

回復 4# jenny1203
1、在Excel說明中輸入「ISERROR」後，按Enter，進入「資訊函數」即可查得函數用法。
2、在Excel說明中輸入「IF」後，按Enter，即可查得函數用法。
請參考！

作者: kkmark696 時間: 2014-7-27 10:31

新手學習中，
感謝分享！

作者: Hsieh 時間: 2014-7-29 10:40

回復 1# ms2001

因為金額可能重複
查詢準則為人員號碼
陣列公式取出資料只能按原資料順序擷取資料
所以，若要結果以金額排序
那就把原資料以金額排序即可
其實這樣的查詢若是資料量大的時候會造成系統負荷過重
利用資料查詢功能是不錯的選擇唷!
[attach]18782[/attach]

作者: 准提部林 時間: 2014-7-30 18:00

本帖最後由准提部林於 2014-7-30 18:02 編輯

＜指定編號篩選，並以金額由大而小排序＞
僅以同一工作表下達公式，不同工作表請自行調整！
Ｇ１：指定人員編號
Ｉ１．符合筆數：=COUNTIF(B:B,G1)

以下公式均下刷完成～～
Ｅ４．序號欄：=ROW(A1)
Ｇ４．金額（由大而小排序）．陣列公式：
　　　=IF(ROW(A1)>I$1,"",LARGE((B$2:B$100=G$1)*C$2:C$100,E4))
Ｆ４．單據號碼．陣列公式：
　　　=IF(G4="","",INDEX(A:A,MOD(SMALL(IF(B$2:B$100=G$1,-C$2:C$100*10^6+ROW($2:$100)),E4),10^6)))
　　　或：
　　　=IF(G4="","",INDEX(A:A,SMALL(IF((B$2:B$100=G$1)*(C$2:C$100=G4),ROW($2:$100)),COUNTIF(G$3:G3,G4)+1)))
　
參考附檔：
[attach]18798[/attach]
http://www.funp.net/207794　
　
註：陣列公式運算耗時，必要時應以VBA處理較合適，
　　另外，透過篩選複製再排序，只要熟練些，也是不錯的方法～～
　

作者: ms2001 時間: 2014-8-11 23:22

太強了，太感謝了~

歡迎光臨麻辣家族討論版版 (http://forum.twbts.com/)