麻辣家族討論版版 - Powered by Discuz! Board

標題: [發問] 如何傳回合條件的日子 [打印本頁]

作者: ffff56666 時間: 2014-7-7 13:31 標題: 如何傳回合條件的日子

大家好, 有沒有方法能將表一合條件的日子傳回表二, 謝謝

作者: p212 時間: 2014-7-8 09:05

本帖最後由 p212 於 2014-7-8 09:12 編輯

回復 1# ffff56666
符合Date of Rainfall > 20mm且排除儲存格內容為「Trace」與「-」之條件，儲存格B43輸入陣列公式 (Ctrl+Shift+Enter)
=IFERROR(SMALL(IF((B$8:B$38>20)*(ISNUMBER(B$8:B$38)),$A$8:$A$38,FALSE),ROW(1:1))&"/"&B$7,"")
向右、向下複製
請參考！

作者: ffff56666 時間: 2014-7-8 12:50

謝謝p212回答, 但在儲存格B43輸入陣列公式 (Ctrl+Shift+Enter)後, 全部顯示為 #NAME?, 同時傳回的日子能否以日期值顯示以方便找出日子是否星期天, 謝謝

作者: ffff56666 時間: 2014-7-8 13:19

原來小弟用excel 2003, 所以沒有IFERROR的, 所以顯示#NAME?, 但傳回的數據能否以日期值顯示呢, 謝謝

作者: p212 時間: 2014-7-8 16:09

本帖最後由 p212 於 2014-7-8 16:15 編輯

回復 4# ffff56666
1、for Excel 2007: 儲存格B43輸入陣列公式 (Ctrl+Shift+Enter)
=IFERROR(DATE(B$6,B$7,SMALL(IF((B$8:B$38>20)*(ISNUMBER(B$8:B$38)),$A$8:$A$38,FALSE),ROW(1:1))),"")
註：您的軟體版本不是標示Office 2007？
2、for Excel 2003: 儲存格B43輸入陣列公式 (Ctrl+Shift+Enter)
=IF(ISERROR(DATE(B$6,B$7,SMALL(IF((B$8:B$38>20)*(ISNUMBER(B$8:B$38)),$A$8:$A$38,FALSE),ROW(1:1)))),"",DATE(B$6,B$7,SMALL(IF((B$8:B$38>20)*(ISNUMBER(B$8:B$38)),$A$8:$A$38,FALSE),ROW(1:1))))

儲存格B43格式之「數值」請設為「日期」，向右、向下複製。
請參考！

作者: ffff56666 時間: 2014-7-8 19:39

成功了, 多謝幫忙!
想問問能否在下雨天當中自動傳回多少天是星期天, 及多少天是假期呢, 謝謝

作者: p212 時間: 2014-7-9 09:10

本帖最後由 p212 於 2014-7-9 09:18 編輯

回復 6# ffff56666
1、回傳符合Rainfall > 20mm總天數(第65列)與Rainfall > 20mm之星期日總天數(第64列)：
儲存格B64=SUMPRODUCT((TEXT(B43:B62,"aaa")="週日")*1)
儲存格B65=COUNTIF(B$8:B$38,">20")
向右複製，請參考！
2、至於符合Rainfall > 20mm條件之「假期」計算屬「多對多」，本人暫無解，有請版主、超版指教，謝謝！

作者: ffff56666 時間: 2014-7-9 13:30

謝謝p212兄的指教,小弟已經獲益良多了

作者: samwang 時間: 2014-7-10 10:46

回復 7# p212

至於符合Rainfall > 20mm條件之「假期」計算屬「多對多」，
>> 儲存格 B63=SUMPRODUCT(COUNTIF(B$43:B$62,$L$43:$L$59))
不知是否是這樣的需求嗎?

作者: ffff56666 時間: 2014-7-10 19:25

成功了,謝謝
但還有一個終極問題待各位大大解答, 就是能否將表二的資料扣除了假日及星期天後回傳至表三呢?

作者: p212 時間: 2014-7-10 21:46

本帖最後由 p212 於 2014-7-10 21:51 編輯

回復 10# ffff56666
符合Date of Rainfall > 20mm且排除假日及星期天時，使用 =COUNTIF(B$8:B$38,">20")-SUMPRODUCT(COUNTIF(B$43:B$62,$L$43:$L$59))-SUMPRODUCT((TEXT(B43:B62,"aaa")="週日")*1) 可以？
還是要更短的公式？

作者: p212 時間: 2014-7-10 21:47

本帖最後由 p212 於 2014-7-10 21:49 編輯

回復 9# samwang
没想到這麼簡單！SUMPRODUCT＋COUNTIF
謝謝samwang 大的解惑

作者: ffff56666 時間: 2014-7-11 08:50

再一次多謝p大的解答, 你的公式應是計算合條件的日子總數, 但如果自動將合條件的下雨日期由表二中用公式篩選到表三的話是否能做到的呢?
謝謝

歡迎光臨麻辣家族討論版版 (http://forum.twbts.com/)