標題: [發問] (小問題)多條件averageif怎麼設 [打印本頁]

---

作者: jj369963    時間: 2014-3-30 11:36     標題: (小問題)多條件averageif怎麼設

Dear大大：

問題：想將同時符合"F2入學年"與"F3班級"，參照左邊表格，做"數值"平均，填入F3
目前想到averageif但是不知如何設多條件

參閱附檔

感謝

[attach]17906[/attach]

---

作者: yen956    時間: 2014-3-30 18:29

回復 1# jj369963
試試看:
F3
=INDIRECT(ADDRESS(MATCH(F1&F2,A2:A21&B2:B21,0)+1,3))
按 Ctri+Shift+Enter

---

作者: huijuang    時間: 2014-3-31 09:46

回復 1# jj369963

我的方法如下
=(SUMPRODUCT((入學年=F1)*(班級=F2)*數值))/SUMPRODUCT((入學年=F1)*(班級=F2))

---

作者: ML089    時間: 2014-4-2 21:39

回復 1# jj369963

=AVERAGEIFS(C:C,A:A,F1,B:B,F2)

---

作者: jj369963    時間: 2014-4-14 12:31

回復 4# ML089

Dear大大：

試著用averageifs 函數
but出現錯誤 #NAME?
可以請問如何修正嗎？

謝謝

---

作者: jj369963    時間: 2014-4-14 12:32

回復 3# huijuang


Dear大大：

我有試著用sumproduct ，不過還是失敗。
可以請問該如何修改呢？
3Q3Q

---

作者: ML089    時間: 2014-4-14 14:59

本帖最後由 ML089 於 2014-4-14 15:04 編輯

回復 5# jj369963

EXCEL 2003 沒有 averageifs 這函數


=AVERAGE(IF((A2:A21=F1)*(B2:B21=F2),C2:C21))
以CTRL+SHIFT+ENTER輸入公式

---

作者: 准提部林    時間: 2014-4-14 15:21

條件式平均值：
Ａ        Ｂ        Ｃ        Ｄ        Ｅ        Ｆ
年級        班級        分數                年級        1
1        3        84                班級        3
1        3        82                平均        87
1        3        95                       
2        4        70                       
2        4        52                       
2        4        99                       
2        4        71                       
2        4        82                       
3        5        90                       
3        5        55                       
　
Ｆ３．陣列公式：
=AVERAGE(IF((A2:A11=F1)*(B2:B11=F2)*(C2:C11<>""),C2:C11))
　
*(C2:C11<>"")　目的：防止〔分數〕空格時誤判為０分！
　　
■陣列公式輸入法：
　輸入或修改公式完成後，游標留在〔編輯列〕，先不要按Enter，
　同時按住〔Shift + Ctrl〕不放，再按〔Enter〕。
　

---

歡迎光臨 麻辣家族討論版版 (http://forum.twbts.com/)