標題: [發問] 請問要如何帶出運費單價? [打印本頁]

---

作者: mrcv3    時間: 2014-2-9 21:03     標題: 請問要如何帶出運費單價?

本帖最後由 mrcv3 於 2014-2-9 21:05 編輯

請問各位大大

運費1
第1區，當天板數9板，故運費單價為700

[attach]17457[/attach]

運費2
第3區，當天重量6257，重量在5000以上，故運費單價為0.95

[attach]17458[/attach]

該如何設定才能帶出運費單價? 謝謝

[attach]17459[/attach]

---

作者: aer    時間: 2014-2-11 15:58

本帖最後由 aer 於 2014-2-11 16:01 編輯

回復 1# mrcv3

運費1 表格建議修改如下圖內容,並增加輔助欄區別

[attach]17467[/attach]

E15=IF(C15>="第7區",IF(SUMIFS($D$15:$D$22,$C$15:$C$22,$C15)<=3,INDEX($N$2:$Q$5,MATCH(SUMIFS($D$15:$D$22,$C$15:$C$22,$C15),$N$2:$N$5,0),MATCH($B15,$N$2:$Q$2,0)),($D15-$N$5)*1500+5000),INDEX($A$2:$L$12,MATCH(SUMIFS($D$15:$D$22,$C$15:$C$22,$C15),$A$2:$A$12,0),MATCH($B15,$B$2:$L$2,0)+1))
向下複製

運費2表格建議修改如下圖內容

[attach]17470[/attach]

D7=IF(SUMIFS($C$7:$C$11,$B$7:$B$11,$B7)>=5000,INDEX($A$2:$O$4,3,MATCH($B7,$B$2:$O$2,0)+1),INDEX($A$2:$O$4,2,MATCH($B7,$B$2:$O$2,0)+1))
向下複製

[attach]17469[/attach]

---

作者: Hsieh    時間: 2014-2-12 10:44

回復 1# mrcv3

建議表格能有一致性，試試附件
    [attach]17478[/attach]

---

作者: aer    時間: 2014-2-12 13:21

回復 3# Hsieh

請教超級版主有合併儲存格的值是怎麼找出來的呢？謝謝

---

作者: mrcv3    時間: 2014-2-12 23:46

謝謝各位大大的幫忙

---

作者: Hsieh    時間: 2014-2-13 09:04

回復 4# aer

看到x定義名稱公式
若作用中儲存格式第15列，其中
LOOKUP(9.9E+307,$A$1:$A15)
會找到15列往上最先找到的數值
也就找到合併儲存格第一個位置的值
而D欄的公式內
LOOKUP("龘",OFFSET($B$1,,,,MATCH($B15,$B$2:$Q$2,0)))
MATCH($B15,$B$2:$Q$2,0)這樣會在第2列找到地區名稱的位置
OFFSET($B$1,,,,MATCH($B15,$B$2:$Q$2,0))就會從B1開始擴展成MATCH($B15,$B$2:$Q$2,0)的範圍做LOOKUP的搜尋範圍
LOOKUP("龘",OFFSET($B$1,,,,MATCH($B15,$B$2:$Q$2,0)))
就在該範圍內找到最後的文字，就得到區域別
在此更正附件內D15的公式
=(MATCH(B15,$B$2:$Q$2,0)>13)*(MAX(0,(C15-3))*1500+5000)+(MATCH(B15,$B$2:$Q$2,0)<13)*(INDEX($B$3:$Q$12,SUMIF(x,LOOKUP("龘",OFFSET($B$1,,,,MATCH($B15,$B$2:$Q$2,0))),$C$15:$C$65536),MATCH(LOOKUP("龘",OFFSET($B$1,,,,MATCH($B15,$B$2:$Q$2,0))),$B$1:$Q$1,0)))
把計算C欄範圍擴充到工作表總列數

---

作者: aer    時間: 2014-2-15 14:41

回復 6# Hsieh

謝謝超級版主的解說！
還有三個問題請教：
① 有關名稱 X 為何切換到不同的工作表時，其定義名稱的參考位置會自動改變，這樣的設計方式有什麼資料可以參考？
② 是否二個工作表皆定義為同一個名稱？但是，定義的範圍不同？如果是的話，又要如何來辨別當前所選擇的工作表是那一個？該用那一個名稱範圍呢？
③ 就是lookup_value 為什麼要用中文字？是因為要查詢的原始資料是文字格式的關係嗎？還有為什麼要用"龘"這個字？其他字是否也可以？或是只要輸入比劃多一點的中文字即可？我有試著將中文字改為"鑫"，也是一樣可以使用。不了解此設計的用意為何？煩請指教，感謝您！

---

作者: Hsieh    時間: 2014-2-15 20:34

回復 [urltex87883828=http://forum.twbts.com/redirect.php?goto=findpost&pid=64048&ptid=11208]7#[/url] aer

x名稱之所以可以當選擇不同工作表亦可自動變化工作表參照
這是因為相對參照格式所致，看到名稱的公式
範圍參照前加上！，這樣的參照樣式只能在定義名稱使用
意思是當前作用中工作表的參照
lookup中使用龘字做為搜尋值，因為此字是個人所知最大的字碼
所以在搜尋時就不會因為資料中出現更大的字碼，當然，如果你確定資料中最大的字碼
用大於等於該字做搜尋值亦可，若是要搜尋資料中最後的數值
則使用EXCEL容許的最大值9.9E+307

---

作者: aer    時間: 2014-2-16 13:29

回復 8# Hsieh

謝謝超級版主的解惑！感恩

---

歡迎光臨 麻辣家族討論版版 (http://forum.twbts.com/)