標題: [發問] 想請教如何顯示各品項到期天數前3名及後3名 [打印本頁]

---

作者: sto3688    時間: 2014-1-28 11:20     標題: 想請教如何顯示各品項到期天數前3名及後3名

想請教如何顯示各品項到期天數前3名及後3名
品項        批號        區域        exp day
A        13A258        E1        30
A        22D365        E1        20
A        31W111        E1        5
A        DA33        E1        8
A        6W214        E1        7
A        33ST5        E1        111
A        P368H        B1        199
A        336DD        B1        333
A        WI241        B1        681
B        S68        E1        3
B        S663        E1        11
B        E624        E1        23
B        FF358        E1        88
B        FT82        E1        168
B        IO698        E1        330
B        JU351        B1        587
B        TE232        B1        98
B        WR338        B1        60
B        Q568E        B1        1
小弟只會用MAX&MIN顯示天數,無法依品項來顯示天數
有請高手幫忙,感恩

---

作者: Hsieh    時間: 2014-1-28 16:15

回復 1# sto3688

[attach]17391[/attach]
[attach]17392[/attach]
增加E欄作輔助欄
E1=COUNTIF($A$1:A1,A1)向下複製
建立名稱:
品項=OFFSET(工作表1!$A$1,,,COUNTA(工作表1!$A:$A),)   
G1陣列公式
=IF(ROW()<=(SUMPRODUCT(1/COUNTIF(品項,品項))-1)*3+1,INDEX(品項,SMALL(IF($E$1:$E$20<=3,ROW($E$1:$E$20),""),ROW(A1)),),"")
向下複製
J2陣列公式
=IF(G2="","",SMALL(IF(品項=G2,$D$1:$D$20,""),COUNTIF($G$1:G2,G2)))
向下複製
O2陣列公式
=IF(G2="","",LARGE(IF(品項=G2,$D$1:$D$20,""),COUNTIF($G$1:G2,G2)))
向下複製
H2陣列公式
=IF($G2="","",INDEX($A$1:$D$20,SMALL(IF(($A$2:$A$20=$G2)*($D$2:$D$20=$J2),ROW($D$2:$D$20),""),SUMPRODUCT(($G$2:G2=$G2)*($J$2:J2=$J2))),COLUMN(B$1)))
向下向右複製
M2陣列公式
=IF($G2="","",INDEX($A$1:$D$20,SMALL(IF(($A$2:$A$20=$G2)*($D$2:$D$20=$O2),ROW($D$2:$D$20),""),SUMPRODUCT(($G$2:G2=$G2)*($O$2:O2=$O2))),COLUMN(B$1)))
向下向右複製

---

作者: sto3688    時間: 2014-1-28 22:23

感謝Hsieh 大,問題已解決,感恩

---

歡迎光臨 麻辣家族討論版版 (http://forum.twbts.com/)