標題: [發問] 如何利用函數自動做資料剖析 [打印本頁]

---

作者: williampeng    時間: 2014-1-27 15:02     標題: 如何利用函數自動做資料剖析

各位好

                   我有一個日常要做的資料，於系統抓下時資料都在第一個欄位，必須使用資料剖析才能再拿來做比對

                  是否能有函數能將資料自動剖析後放入另一個工作表中?

                    請參考附件檔  Sample    其中 "Raw data" 就是系統抓下的資料 "資料清單" 就是希望整理好的狀況

                    請高手指點迷津  [attach]17380[/attach]

---

作者: williampeng    時間: 2014-2-5 15:14

敢問高手們，此題無解嗎?

---

作者: aer    時間: 2014-2-6 13:29

回復 1# williampeng

試試在資料清單工作表的B3 ~ J3 分別輸入以下的公式
B3=TRIM(LEFT('Raw data'!A3,FIND("A",'Raw data'!A3,1)))
C3=TRIM(MID('Raw data'!A3,FIND("T0",'Raw data'!A3,1),4))
D3=TRIM(MID('Raw data'!A3,FIND("已處",'Raw data'!A3,1),FIND("8P",'Raw data'!A3,1)-2-FIND("已處",'Raw data'!A3,1)))
E3=TRIM(MID('Raw data'!A3,FIND("8P",'Raw data'!A3,1)-1,FIND("9100",'Raw data'!A3,1)-FIND("8P",'Raw data'!A3,1)-1))
F3=VALUE(MID('Raw data'!A3,FIND("9100",'Raw data'!A3,1),4))
G3=VALUE(MID('Raw data'!A3,FIND("9100",'Raw data'!A3,1)+4,(FIND("KG",'Raw data'!A3,1)-3-FIND("9100",'Raw data'!A3,1)-3)
H3=TRIM(MID('Raw data'!A3,FIND("KG",'Raw data'!A3,1),2))
I3=VALUE(MID('Raw data'!A3,FIND("0",'Raw data'!A3,116),1))
J3=VALUE(RIGHT('Raw data'!A3,1))
向下複製

---

作者: ML089    時間: 2014-2-7 10:00

B3
=IF(COLUMN(A1)<5,TRIM(INDEX(MID('Raw data'!$A3,{1,18,26,51},{15,8,25,30}),COLUMN(A1))),TRIM(MID(SUBSTITUTE(TRIM(MID('Raw data'!$A3,90,999))," ",REPT(" ",99)),(COLUMN(A1)-5)*99+1,99)))

右拉下拉
都是文字格式

---

作者: williampeng    時間: 2014-2-7 13:57

回復 4# ML089


           謝謝版主，可以用了
     公式有點艱深，得好好研究以後才能活用在其他需求上

                  順便拜個晚年，祝福大家新年快樂，萬事如意。

---

作者: ML089    時間: 2014-2-7 15:48

回復 5# williampeng

公式分為2段來看比較容易，
前4個採用固定位置取出，後面以空格(連續空格視為1個)頗開取出
=IF(COLUMN(A1)<5,
TRIM(INDEX(MID('Raw data'!$A3,{1,18,26,51},{15,8,25,30}),COLUMN(A1))),
TRIM(MID(SUBSTITUTE(TRIM(MID('Raw data'!$A3,90,999))," ",REPT(" ",99)),(COLUMN(A1)-5)*99+1,99))
)

---

歡迎光臨 麻辣家族討論版版 (http://forum.twbts.com/)