標題: [發問] VLOOKUP 名稱不重複，數量加總問題 [打印本頁]

---

作者: 天魔黑羽    時間: 2013-9-28 03:02     標題: VLOOKUP 名稱不重複，數量加總問題

各位大大 您好:
如果要使出貨表-1跟出貨表-2共同加總是要用何種函數較為適合?
因為小弟用了VLOOKUP還是無法進行同品項加總只會加總其中1個相似的數值，
而無法加總所有相同的數值!
品名不重複，但出貨總數量會與出貨表-1跟出貨表-2進行加總，請問大大要如何使用?
凡請大大賜教  教教小弟如何進行名稱不重複，數量進行加總!

---

作者: tku0216    時間: 2013-9-28 15:19

試試sumifs函數如附件，不知是否達到你的需求？
但好像有相容性問題，不確定你那邊是否可以看到結果，在"總計"工作表的E1欄位，貼上公式=SUMIFS('出貨表-1'!$E$2:$E$25,'出貨表-1'!$D$2:$D$25,資料庫!$D2)+SUMIFS('出貨表-2'!$E$2:$E$25,'出貨表-2'!$D$2:$D$25,資料庫!$D2)， 之後往下複製。
[attach]16194[/attach]

---

作者: ML089    時間: 2013-9-28 16:01

回復 1# 天魔黑羽
   
E2 =SUMPRODUCT(SUMIF(INDIRECT("'出貨表-"&ROW($1:$2)&"'!C:C"),C2,INDIRECT("'出貨表-"&ROW($1:$2)&"'!E:E")))
下拉

當有多表格有序號規則時，可以用此式擴充

---

作者: 天魔黑羽    時間: 2013-9-29 00:52

回復 2# tku0216

大大 您好 :
我測試結果好向會出現亂碼，無法正確顯示該數值。

---

作者: 天魔黑羽    時間: 2013-9-29 00:54

回復 3# ML089


大大 您好:
你的解答函數，正是小弟想要的函數，但是想請問是否有甚麼設定可自動將有數量的品名，進行顯示而不重複呢?

---

作者: ML089    時間: 2013-9-29 14:26

回復 5# 天魔黑羽
[attach]16198[/attach]

請參考檔案說明

Sheet:資料庫

增加E(出貨數量)、F(序號輔助欄)、G(出貨表名稱)等三欄位               
黃色區為公式如下               

E2 =SUMPRODUCT(SUMIF(INDIRECT("'"&出貨表名稱&"'!C:C"),B2,INDIRECT("'"&出貨表名稱&"'!E:E")))               
F2 =N(F1)+(E2>0)               
名稱定義:               
出貨表名稱        =OFFSET(資料庫!$G$2,,,COUNTA(資料庫!$G:$G)-1)       

---------------------------------------------------------
Sheet:總計

A2 =IF(ROW(A1)>MAX(資料庫!F:F),"",ROW(A1))
C2 =IF(A2="","",INDEX(資料庫!B:B,MATCH(A2,資料庫!F:F,)))
D2 =IF(A2="","",INDEX(資料庫!D:D,MATCH(A2,資料庫!F:F,)))
E2 =IF(A2="","",INDEX(資料庫!E:E,MATCH(A2,資料庫!F:F,)))

---

作者: 天魔黑羽    時間: 2013-9-30 00:42

回復 6# ML089

大大您好 :

檔案小弟無法下載，但想請問一下我再新增其他出貨表時，進行加總，卻無法進行加總卻出現錯誤，這要如何進行函數公式串聯呢?
還有一個就是(出貨表-)這個是對應哪個頁籤的?因為只要頁籤修改...該函數位置會出現錯誤!
煩請大大賜教!

---

作者: ML089    時間: 2013-9-30 07:19

回復 7# 天魔黑羽

Sheet: 資料庫
G欄(出貨表名稱)，就是由G2開始填入你要統計的出貨表名稱，這樣增減比較有彈性，出貨表名稱修改時這裡也要同步修改才不會造成錯誤。

例如
出貨表-1
出貨表-2
...

---

作者: 天魔黑羽    時間: 2013-9-30 12:21

回復 8# ML089

謝謝大大，讓小弟學到函數公式方式!

---

歡迎光臨 麻辣家族討論版版 (http://forum.twbts.com/)