Board logo

標題: 求助尋找第二筆資料的寫法 [打印本頁]
作者: yan2463    時間: 2013-9-25 13:39     標題: 求助尋找第二筆資料的寫法

求助尋找第二筆資料的寫法
   另可否加助說明
   (因為尚有其他需要運用)[attach]16161[/attach]
作者: Hsieh    時間: 2013-9-28 00:44

回復 1# yan2463

[attach]16192[/attach]
B2陣列公式
=INDIRECT("評等表!R"&SMALL(IF(--評等表!$A$4:$A$39=問題二!$A$2,ROW($4:$39),""),INT((COLUMN()-2)/3)+1)&"C"&COLUMN()+1-INT((COLUMN()-2)/3)*3,0)   

其中
SMALL(IF(--評等表!$A$4:$A$39=問題二!$A$2,ROW($4:$39),""),INT((COLUMN()-2)/3)+1)
會取得符合條件的第?小列號
因為B:D欄為第一筆資料所以用INT((COLUMN()-2)/3)+1來取得
至於引用到INDIRECT參數部分，有列號後就只要三欄一組並以3、4、5為欄號
COLUMN()+1-INT((COLUMN()-2)/3)*3
這樣就能向左以3、4、5、3、4、5....這樣排列了
作者: ML089    時間: 2013-9-28 15:42

B2 一般公式 (當股票有排列在一起時)
=IF(COLUMN(A2)/3>COUNTIF(評等表!$A:$A,$A2),"",INDEX(評等表!$C:$E,MATCH($A2&"",評等表!$A:$A,)+INT((COLUMN(A2)-1)/3),MOD(COLUMN(A2)-1,3)+1))

右拉複製公式(有幾筆需求就右拉幾筆)
作者: yan2463    時間: 2013-9-30 14:55

感謝兩位提供的方法
正在使用中
作者: yan2463    時間: 2013-9-30 15:21

請問狀況五中代號及文字
如何才能用此公式
作者: yan2463    時間: 2013-9-30 15:58

回復 2# Hsieh
感謝你的解答,但是我還是不懂吔
可否再教我狀況二的寫法
作者: yan2463    時間: 2013-9-30 16:01

回復 3# ML089
請問我試用你的方法時,
如果評等表中資料只有一筆時,最後一欄(目標價)資料會帶不出來
如果只有兩筆時,第二筆資料,最後一欄(目標價)資料會帶不出來
作者: ML089    時間: 2013-9-30 17:52

回復 7# yan2463

我試過不會有此問題 ?
請將檔案PO上來看看
作者: yan2463    時間: 2013-10-1 09:00

[attach]16204[/attach]回復 8# ML089
已上傳檔案,再麻煩了
另狀況五是否可以幫忙解答
作者: ML089    時間: 2013-10-1 20:07

回復 9# yan2463

你EXCEL表所用的C6公式
=IF(COLUMN(B6)/3>COUNTIF(評等表!$A:$A,$B6),"",INDEX(評等表!$C:$E,MATCH($B6&"",評等表!$A:$A,)+INT((COLUMN(B6)-2)/3),MOD(COLUMN(B6)-2,3)+1))

我原PO的公式
=IF(COLUMN(A2)/3>COUNTIF(評等表!$A:$A,$A2),"",INDEX(評等表!$C:$E,MATCH($A2&"",評等表!$A:$A,)+INT((COLUMN(A2)-1)/3),MOD(COLUMN(A2)-1,3)+1))

COLUMN(A2) 為計數器被改為 COLUMN(B6) 當然會差一位

C6公式請修改如下
=IF(COLUMN(A6)/3>COUNTIF(評等表!$A:$A,$B6),"",INDEX(評等表!$C:$E,MATCH($B6&"",評等表!$A:$A,)+INT((COLUMN(A6)-1)/3),MOD(COLUMN(A6)-1,3)+1))

另外狀況五晚一點我有空再看看
作者: ML089    時間: 2013-10-1 20:12

本帖最後由 Hsieh 於 2013-12-11 23:42 編輯

AF27公式
=IF(COLUMN(A27)/3>COUNTIF(評等表!$A:$A,LEFT($T27,4)),"",INDEX(評等表!$C:$E,MATCH(LEFT($T27,4),評等表!$A:$A,)+INT((COLUMN(A27)-1)/3),MOD(COLUMN(A27)-1,3)+1))

右拉複製公式
作者: yan2463    時間: 2013-10-2 13:14

回復 11# ML089
真的感謝,已完全可以用了
作者: yan2463    時間: 2013-12-11 16:34

回復 12# yan2463
再請教一個問題,若我想把資訊增加到H欄(6欄為一組)
我要改那個地方
作者: yan2463    時間: 2013-12-12 11:31

回復 11# ML089
想再請教一個問題,想增加資訊6欄為一組,
應該修改那裡
作者: ML089    時間: 2013-12-12 13:50

回復 14# yan2463

C6
原為
=IF(COLUMN(B6)/3>COUNTIF(評等表!$A:$A,$B6),"",INDEX(評等表!$C:$E,MATCH($B6&"",評等表!$A:$A,)+INT((COLUMN(B6)-2)/3),MOD(COLUMN(B6)-2,3)+1))
改為
=IF(COLUMN(B6)/6>COUNTIF(評等表!$A:$A,$B6),"",INDEX(評等表!$C:$H,MATCH($B6&"",評等表!$A:$A,)+INT((COLUMN(B6)-2)/6),MOD(COLUMN(B6)-2,6)+1))
作者: yan2463    時間: 2013-12-17 09:18

回復 15# ML089
感謝正在使用中



歡迎光臨 麻辣家族討論版版 (http://forum.twbts.com/)