標題: [發問] VLOOKUP參照檢視問題 [打印本頁]

---

作者: nbe7253    時間: 2010-8-11 00:29     標題: VLOOKUP參照檢視問題

本帖最後由 Hsieh 於 2010-8-11 08:42 編輯

請教各位先進們，小弟有個VLOOKUP查詢問題如下表所示
如何能同時顯示同為33的CC及FF資料
公式為F8=VLOOKUP($E8,$A$1:$B$10,2,FALSE)
         E8=LARGE($A$1:$A$10,D8)
感謝各位回覆

11        AA                1        99        YY
22        BB                2        88        JJ
33        CC                3        77        HH
33        FF                4        66        GG
44        DD                5        55        EE
55        EE                6        44        DD
66        GG                7        33        CC
77        HH                8        33        CC
88        JJ                9        22        BB
99        YY                10        11        AA

---

作者: PD961A    時間: 2010-8-11 07:13

回復 2# nbe7253


    編輯帖子選擇"禁用"表情


[attach]2334[/attach]

---

作者: kimbal    時間: 2010-8-11 07:51

回復 1# nbe7253

會建議用自動/進階篩選

公式的話:假設的公式在F1
=INDEX($A$1:$C$10,SMALL(IF($A$1:$C$10=33,ROW($A$1:$C$10),ROW($C$10)+1),ROW()),2)
陣列公式,要按CTRL+SHIFT+ENTER

然後把F1的公式向下抄,就會出現第2個答案.

---

作者: ivanyung    時間: 2010-8-11 13:34

同樣建議用 filter ...
另一類公式
要用陣列
公式在 f1:

1. =INDIRECT("b"&LARGE(($A$1:$A$10=33)*($B$1:$B$10={"CC","FF"})*ROW($A$1:$A$10),ROW(A1)))

複製代碼

---

作者: nbe7253    時間: 2010-8-11 23:04

本帖最後由 nbe7253 於 2010-8-11 23:09 編輯

回復 2# PD961A 感謝PD961A 大的協助
回復 3# kimbal
回復 4# ivanyung

感謝二位的解答！但並不是我要的公式
可能是小弟的表示有誤！
問題如下
當分數在排序時成績
可能有2個或3個以上是相同時
能同時秀出成績相同的每個人名稱
因資料會常異動所以重複的名字也會不同
在次感謝大家

[attach]2364[/attach]

---

作者: Hsieh    時間: 2010-8-11 23:53

E2=LARGE($A$2:$A$11,D2)
F2陣列公式
{=INDIRECT("B"&SMALL(IF($A$2:$A$11=LARGE($A$2:$A$11,D2),ROW($A$2:$A$11)),COUNTIF($E$1:E1,LARGE($A$2:$A$11,D2))+1))}

---

作者: asimov    時間: 2010-8-11 23:56

回復 5# nbe7253


A欄必須是數字
試試
E2=LARGE($A$2:$A$16,ROW(A1))
F2用陣列公式
{=INDEX($B$2:$B$16,SMALL(IF($A$2:$A$16=E2,ROW($A$2:$A$16)-1),COUNTIF($E$2:E2,E2)))}

---

作者: nbe7253    時間: 2010-8-12 00:32

回復 6# Hsieh
回復 7# asimov


感謝Hs超級版主、asimov大
小弟授教

---

歡迎光臨 麻辣家族討論版版 (http://forum.twbts.com/)