Board logo

標題: 平均值 [打印本頁]
作者: myleoyes    時間: 2010-8-8 08:38     標題: 平均值

各位前輩你們好!
         前輩!問題如附檔案說明
         A18=IF(A8=0,"",A8/COUNTIF(B1:AI1,"差額"))
         請知道的前輩,不吝賜教謝謝再三!!
作者: kimbal    時間: 2010-8-8 11:05

各位前輩你們好!
         前輩!問題如附檔案說明
         A18=IF(A8=0,"",A8/COUNTIF(B1:AI1,"差額"))
...
myleoyes 發表於 2010-8-8 08:38



    可以說一下a4/a6/a8是在做什麼嗎?
a11 是不是找b,e,h...的平均值 (差額當成1?) ?
a14 是不是找c,f,i...的平均值?
a18 是不是找d,g,j...的平均值?
作者: luhpro    時間: 2010-8-8 12:04

本帖最後由 luhpro 於 2010-8-8 12:15 編輯

經觀察你的
A4 = SUMPRODUCT(0,8,0,0,6,0,0,0,0,...})
亦即將 C1,F1,I1,... 加總  (因為 "差額" 只會在B1,E1,H1...產生,所以在A4應無作用)
A6 = SUMPRODUCT({0,0,2,0,0,2,0,0,0,...})
亦即將 D1,G1,J1,... 加總 (理由同上)

所以我猜你要的是底下的公式
A11=A4/(COUNTA($B$1IV$1)/3)
A14=A6/(COUNTA($B$1IV$1)/3)
另外因為 A8=A4-A6 亦即為兩個加總數字的差額,
似乎與 "差額" 的個數無關,
這裡不太清楚你用 COUNTIF(B1:AI1,"差額") 當分母的原因.
作者: myleoyes    時間: 2010-8-8 12:19

回復 2# kimbal
kimbal前輩你好!
       前輩!謝謝!
       A4是c,f,i...的總和
       所以A11=A4/8平均值是6.25
       A6是找d,g,j...的總和
       所以A14=A6/8平均值是3
       A8是b,e,h...的總和
       把"差額"當成0計算
       所以A17=A8/7平均值是3.43
       以範例檔A17來說小弟用此公式
       A17=IF(A8=0,"",A8/COUNTIF(B1:AI1,"差額"))
       計算出來是4.8,但實際是3.43
       因為B1:AK1之間有"差額"的共有12個儲存格
       然而有數字的共有7個所以24/7=3.43
       小弟用的公式找到的是5個除出來當是錯
       請不吝賜教謝謝再三!!
作者: myleoyes    時間: 2010-8-8 16:17

回復 4# myleoyes
luhpro前輩你好!
　　　　 前輩!謝謝!
         這裡不太清楚你用 COUNTIF(B1:AI1,"差額") 當分母的原因
         因為B1:AK1之間有"差額"的儲存格共有12個
         而且A8是b,e,h...的總和,所以A8/有7個沒有差額的儲存格
         就是平均值,如果公式改成A8/COUNTIF(B1:AI1,"<>差額")
         也不對阿!因為B1:AK1之間沒有差額的儲存格有31個
         因為找不到公式所以才求助各前輩
         請不吝賜教謝謝再三!!
作者: asimov    時間: 2010-8-8 19:23

本帖最後由 asimov 於 2010-8-8 19:40 編輯

回復 4# myleoyes


試試
A11
=IF(A4=0,"",A4/SUMPRODUCT((MOD(COLUMN($B$1:$AK$1),3)=0)*($B$1:$AK$1>0)))
A14
=IF(A6=0,"",A6/SUMPRODUCT((MOD(COLUMN($B$1:$AK$1)-1,3)=0)*($B$1:$AK$1>0)))
A17
=IF(A8=0,"",A8/SUMPRODUCT((MOD(COLUMN($B$1:$AK$1)+1,3)=0)*ISNUMBER($B$1:$AK$1)))
作者: asimov    時間: 2010-8-8 19:46

用同樣的公式可以簡化A4,A6,A8
A4
=SUMPRODUCT((MOD(COLUMN($B$1:$AK$1),3)=0)*ISNUMBER($B$1:$AK$1),$B$1:$AK$1)
A6
=SUMPRODUCT((MOD(COLUMN($B$1:$AK$1)-1,3)=0)*ISNUMBER($B$1:$AK$1),$B$1:$AK$1)
A8
=SUMPRODUCT((MOD(COLUMN($B$1:$AK$1)+1,3)=0)*ISNUMBER($B$1:$AK$1),$B$1:$AK$1)
作者: myleoyes    時間: 2010-8-9 20:53

回復 7# asimov
asimov前輩你好!
　　　　 前輩!謝謝!可以囉!!謝謝再三!!
作者: zz5151353    時間: 2010-8-12 00:07

本帖最後由 zz5151353 於 2010-8-12 21:07 編輯

A4 公式
=SUMPRODUCT(N(OFFSET(C1,,(ROW(1:50)-1)*3,,)))
A6 公式
=SUMPRODUCT(N(OFFSET(D1,,(ROW(1:50)-1)*3,,)))
A11 公式
{=AVERAGE(IF(N(OFFSET(C1,,(ROW(1:50)-1)*3,,)),N(OFFSET(C1,,(ROW(1:50)-1)*3,,))))}
A14 公式
{=AVERAGE(IF(N(OFFSET(D1,,(ROW(1:50)-1)*3,,)),N(OFFSET(D1,,(ROW(1:50)-1)*3,,))))}
A17 公式
{=AVERAGE(IF((N(OFFSET(D1,,(ROW(1:50)-1)*3,,)))-(N(OFFSET(C1,,(ROW(1:50)-1)*3,,))),N(OFFSET(C1,,(ROW(1:50)-1)*3,,))-N(OFFSET(D1,,(ROW(1:50)-1)*3,,))))}
作者: myleoyes    時間: 2010-8-12 21:19

回復 9# zz5151353
zz5151353前輩你好!
      前輩!!謝謝!歹勢!一忙忘了回覆
      拖到現在公式正是需求謝謝再三!!



歡迎光臨 麻辣家族討論版版 (http://forum.twbts.com/)