返回列表 上一主題 發帖

大量資料排名

大量資料排名

各位先進好
我想要把H欄位裡排名顯示在J欄
但因為資料太多常常會有達50萬個數字(資料數不一定)
用函數方式處理常常會當掉
不知如何改成VBA的方式自動計算
函數式:"=IF(H6="",0,SUMPRODUCT(($H$6:$H$500000>=H6)*(1/COUNTIF(H$6:H$500000,H$6:H$500000))))"

1100927-排名.rar (540.57 KB)

本帖最後由 ML089 於 2021-10-19 16:44 編輯

10萬筆資料,唯一值有1萬筆,排名比較
排序採用 Range.Sort   執行時間  0.3"
排序採用 System.collections.arraylist    執行時間  0.33"
排序採用 Large函數 執行時間 30"
結論 Range.Sort 也不慢

原資料10萬筆只有6筆是唯一值,這樣測不出效率,
其實唯一值小於10筆用函數也可以 0.3",唯一值為1萬筆需要46秒

Sub 排名AmoKat()
    tm = Timer
    Set xD = CreateObject("Scripting.Dictionary")
    Arr = Range([h6], [h1].Cells(Rows.Count, 1).End(xlUp))
    For i = 1 To UBound(Arr): xD(Arr(i, 1)) = 0: Next i '字典產生唯一值
    With [i6].Resize(xD.Count) '利用 Range.Sort 排序
        .Value = Application.Transpose(xD.keys)
        .Sort Key1:=.Item(1), Order1:=xlDescending, Header:=xlNo
    End With
    For i = 1 To xD.Count: xD(Cells(5 + i, "I").Value) = i: Next i '排序序號寫入字典
    For i = 1 To UBound(Arr)    '查詢字典排列序號
        If Arr(i, 1) = "" Then Arr(i, 1) = 0 Else Arr(i, 1) = xD(Arr(i, 1))
    Next i
    [i6].Resize(UBound(Arr)) = Arr '貼上資料
    Set xD = Nothing: Erase Arr
    Debug.Print Timer - tm    '0.30"
End Sub
{...} 表示需要用 CTRL+SHIFT+ENTER 三鍵輸入公式

TOP

'參考 ikboy 學習System.collections.arraylist
Sub 排名AmoKat修改()
    tm = Timer
    Dim d As Object, a, k, t, xL As Object, n&
   
    a = Range("h6:h" & [h1048576].End(3).Row)
   
    Set d = CreateObject("scripting.dictionary") '字典取唯一值
    For Each k In a: If k <> "" Then d(k) = 0: Next
   
    Set xL = CreateObject("System.collections.arraylist") '排序作業
    For Each k In d.keys: xL.Add k: Next
    xL.Sort     'Sorted Ascending
    xL.Reverse  'Reverse sort
    For i = 1 To xL.Count: d(xL(i - 1)) = i: Next '排序序號(排名)寫入字典
   
    For i = 1 To UBound(a)
        If a(i, 1) = "" Then a(i, 1) = 0 Else a(i, 1) = d(a(i, 1)) '排名寫入a陣列
    Next
    [i6].Resize(UBound(a)) = a 'a陣列寫入 I 欄位
    Debug.Print Timer - tm, "End"  '31.40" 改善為 0.332"
End Sub
{...} 表示需要用 CTRL+SHIFT+ENTER 三鍵輸入公式

TOP

回復 18# 准提部林


    謝謝你

TOP

回復 17# oak0723-1


Private Sub Worksheet_Change(ByVal Target As Range)
With Target
     If .Column <> [h1].Column Then Exit Sub
     If .Row < 6 Or .Count > 1 Then Exit Sub
     Call 排名test02
End With
End Sub

資料量大的話, 少用事件觸發, 數據完成後用按鈕較適妥

TOP

回復 13# 准提部林


    想利用事件觸發排名巨集
當 H 欄內容改變就觸發執行"排名teat02"巨集
如何使用事件觸發?
若不用事件觸發,要如何觸發?
Image 1011-1.jpg

1101005-(絕對)比對複製QA.rar (258.95 KB)

TOP

回復 11# samwang


    是的
都有符合
因為發現時文章已超過15分鐘
無法刪除
所以很對不起

TOP

回復 12# samwang


    確實速度有變得更快
非常感謝
對我幫助非常大

TOP

回復 13# 准提部林


    謝謝關注
感謝熱心回復

TOP

Sub 排名()
Dim Arr, Brr, xD, V&, i&, j&, k&, N&
Set xD = CreateObject("Scripting.Dictionary")
Arr = Range([h1], [h1].Cells(Rows.Count, 1).End(3))
ReDim Brr(1 To UBound(Arr) + 1)
For i = 6 To UBound(Arr)
    If Arr(i, 1) = "" Then GoTo i01
    V = Arr(i, 1)
    If xD.Exists(V) Then GoTo i01 Else xD(V) = "": N = N + 1
    For j = N To 1 Step -1
        If V >= Brr(j) Then Brr(j + 1) = Brr(j) Else Exit For
    Next j
    Brr(j + 1) = V
i01: Next i
xD.removeall
For j = 1 To N: xD(Brr(j)) = j: Next
'------------------------------------
For i = 6 To UBound(Arr)
    V = xD(Arr(i, 1))
    If Arr(i, 1) = "" Then V = 0
    Arr(i - 5, 1) = V
Next i
[i6].Resize(UBound(Arr) - 5) = Arr
Set xD = Nothing: Erase Arr, Brr
End Sub


=====================================

TOP

        靜思自在 : 【做人的開始】每一天都是故人的開始,每一個時刻都是自己的警惕。
返回列表 上一主題