返回列表 上一主題 發帖

求每月最大與最小NO之計算

求每月最大與最小NO之計算

問題:求每月最小與最大NO,漏掉NO與計數?

求每月最大與最小NO之計算.zip (55.78 KB)

希望支持!

H3:I3 {=QUARTILE(IF(($G3=$A$2:$A$2336)*(H$1=MID($D$2:$D$2336,4,2)),--$B$2:$B$2336),{0,4}) }
選擇H3:I3這2格,陣列公式輸入, CTRL、SHIFT先按不放,在按ENTER輸入
選擇H3:I3這2格下拉

J3 {=IF(I3-H3+1=K3,"",LOOKUP(1,0/(FREQUENCY(IF(($G3=$A$2:$A$2336)*(H$1=MID($D$2:$D$2336,4,2)),--$B$2:$B$2336),ROW(INDIRECT(H3&":"&I3-1)))=0),ROW(INDIRECT(H3&":"&I3)))) }
只能求出缺數最後一個
陣列公式輸入, CTRL、SHIFT先按不放,在按ENTER輸入
下拉

K3 {=COUNT(0/FREQUENCY(IF(($G3=$A$2:$A$2336)*(H$1=MID($D$2:$D$2336,4,2)),--$B$2:$B$2336),--$B$2:$B$2336)) }
陣列公式輸入, CTRL、SHIFT先按不放,在按ENTER輸入
下拉

求每月最大與最小NO之計算_KK.rar (58.94 KB)
{...} 表示需要用 CTRL+SHIFT+ENTER 三鍵輸入公式

TOP

ML089大大,漏掉數,是要扣掉,没說清楚,但公式,若漏在當月最後一筆,無法顯示,那如果漏掉二筆以上,函數是否足以應付?
希望支持!

TOP

本帖最後由 s7659109 於 2018-8-21 07:55 編輯

增加漏號多筆時,無法篩選出來,另若當月漏在最後一筆也無法顯示,另外計數要將漏號扣除

求每月最大與最小NO之計算0821 (2).zip (60.03 KB)

希望支持!

TOP

回復 4# s7659109


J3 陣列公式,下拉
=MID(SUBSTITUTE(TEXT(SUM(IFERROR(LARGE((COUNTIFS($A:$A,$G3,$D:$D,LEFT($D3,3)&H$1&"*",$B:$B,ROW(INDIRECT(MAX(1,--H3)&":"&MAX(I3+0,L3-1))))=0) * ROW(INDIRECT(MAX(1,--H3)&":"&MAX(I3+0,L3-1))), ROW($1:$5))*10^{0;3;6;9;12},0)),REPT("、!0!0000",5)),"、00000",""),2,30)

公式假設 RENO是 00nnn 的3位數,最大可以取5缺數。若是 RENO是 nnnnn 的5位數,最大可以取3缺數,需修改公式。


求每月最大與最小NO之計算0821.rar (60.31 KB)
{...} 表示需要用 CTRL+SHIFT+ENTER 三鍵輸入公式

TOP

ML089大大,漏掉數,是要扣掉,没說清楚,但公式,若漏在當月最後一筆,無法顯示,那如果漏掉二筆以上,函數是 ...
s7659109 發表於 2018-8-20 20:37


漏號位於當月最大與下月最小之間?               

號碼檢查方式,本月最小號 至 MAX(本月最大,下月最小-1)。
{...} 表示需要用 CTRL+SHIFT+ENTER 三鍵輸入公式

TOP

ML089大大,謝謝,ok
希望支持!

TOP

若以vba,該如何寫?
希望支持!

TOP

一月最後一號 0012
二月第一號 0015

那0013.0014如何判定是漏在哪一月???
最後一月最後一號0334, 如何判定後面的0335~????是否漏號???
再則有無跨年問題???
EXCEL參考資料:
http://blog.xuite.net/smile1000mile/blog

TOP

問題:
        1.漏號可能在當月之間,也可能在次月之前,若在次月之前歸在前月,以AAA 1月為例,00003、00005在1月間,但00012在2月RENO 00013開始之前                                                                               
        2.新增按日期起訖號編列                                                                               
        無跨年度問題(僅1-12月)

求每月最大與最小NO之計算0822進階版.zip (70.52 KB)

希望支持!

TOP

        靜思自在 : 【是否發揮了良能?】人間壽命因為短暫,才更顯得珍貴。難得來一趟人間,應問是否為人間發揮了自己的良能,而不要一味求長壽。
返回列表 上一主題