麻辣家族討論版版 - Powered by Discuz! Board

標題: 修改程式碼 [打印本頁]

作者: man65boy 時間: 2012-1-8 14:36 標題: 修改程式碼

如何讓以下的程式包含在找不到員工編號，能提醒，希望在多加上如果不想在TextBox3上輸入編號(空白)的意思，就直接在活頁呈現空白的指令，

Private Sub CommandButton1_Click()
On Error Resume Next
'輸入員工編號後用函數來取得員工姓名
ranme = sht2.Cells(WorksheetFunction.Match(TextBox3.Text, sht2.Range("D:D"), 0), "E")
'如果查無員工編號，要求重新輸入員工編號
If ranme = "" Then
      MsgBox "查無員工編號，請重新輸入"
      UserForm1.TextBox3.Text = ""
      UserForm1.TextBox3.SetFocus
      Exit Sub
End If
On Error GoTo 0
With sht1
      .Range("A2") = Me.ComboBox1.List(Me.ComboBox1.ListIndex, 0)
      .Range("A4") = Me.ComboBox1.List(Me.ComboBox1.ListIndex, 1)
      .Range("B4") = TextBox2.Text
      .Range("B7") = ranme '這裡是TextBox3轉寫地方
End With
End Sub

麻煩各位先進們不吝指教~

作者: GBKEE 時間: 2012-1-8 15:47

回復 1# man65boy

Option Explicit
Private Sub CommandButton1_Click()
Dim ranme As Variant
'輸入員工編號後用函數來取得員工姓名
ranme = Application.Match(TextBox3.Text, Sht2.Range("D:D"), 0)
'如找到 ranme->傳回數字 ,否則 ranme ->錯誤值 "# N/A"
If IsError(ranme) Then '如果查無員工編號，要求重新輸入員工編號
MsgBox "查無員工編號，請重新輸入"
UserForm1.TextBox3.Text = ""
UserForm1.TextBox3.SetFocus
Exit Sub
End If
With Sht1
.Range("A2") = Me.ComboBox1.List(Me.ComboBox1.ListIndex, 0)
.Range("A4") = Me.ComboBox1.List(Me.ComboBox1.ListIndex, 1)
.Range("B4") = TextBox2.Text
.Range("B7") = TextBox3 '這裡是TextBox3轉寫地方
End With
End Sub

複製代碼

作者: man65boy 時間: 2012-1-8 19:39

本帖最後由 man65boy 於 2012-1-8 20:47 編輯

回復 2# GBKEE

重點是要:有輸入時，找不到員工編號，能夠提醒，在多加上如果不想在TextBox3上輸入編號，只輸入空白，按OK就直接在活頁呈現空白，

複製老師所改的程式，出現[attach]9147[/attach]，小弟把原始表單移一些過來給老師過目，小弟VBA程度差很多，怕浪費老師的時間，

[attach]9146[/attach]

作者: GBKEE 時間: 2012-1-9 09:47

回復 3# man65boy

Dim sht1 As Worksheet
Dim sht2 As Worksheet
Private Sub ComboBox1_Change()
Dim i As Integer
i = ComboBox1.ListIndex 'ListIndex 屬性用來識別 ListBox 或 ComboBox 中的目前選取專案
With sht1
If i < 0 Then ' -1 時 ComboBox1的選取不在ComboBox1.List的範圍
TextBox3.Text = "" '
.Range("B7") = ""
Else
TextBox3 = ComboBox1.List(i, 1) ' sht2.Range("d2:e" & r).Value: 第2欄:姓名
.Range("B7") = ComboBox1.List(i, 1)
End If
End With
End Sub
Private Sub UserForm_Initialize()
Dim r As Integer
Set sht1 = Sheets("列印")
Set sht2 = Sheets("資料表")
r = sht2.Range("D65536").End(xlUp).Row
With ComboBox1
.List = sht2.Range("D2:E" & r).Value '設置ComboBox1的List的內容
.ColumnCount = 1 '只顯示第1欄:編號 ,第2欄:姓名->不顯示
.Style = 0 'ComboBox 為一個下拉式清單。使用者或從下拉式清單中選取可在文字區輸入 ( 預設 )。 '
.MatchRequired = Fasle 'MatchRequired 屬性為 True，使用者就必須輸入符合清單中既有專案的文字，才可離開 ComboBox。藉著要求使用者選取既有的專案，可以使 MatchRequired 維護清單的完整性。
.TabIndex = 1 '設定在表單中的定位順序。
End With
End Sub
Private Sub CommandButton2_Click()
Unload Me
End Sub

複製代碼

作者: man65boy 時間: 2012-1-9 21:27

本帖最後由 man65boy 於 2012-1-10 19:22 編輯

回復 4# GBKEE

感謝GBKEE大大的回答，想請大大在修改一些，小弟可能把範例多加了ComboBox1下拉，拍事，小弟錯看程式需要ComboBox1，不過也謝謝大大給了小弟不錯的範例，我再把檔案重新上傳，這次部會錯了。

作者: Hsieh 時間: 2012-1-9 22:57

回復 5# man65boy

Private Sub CommandButton1_Click()
Dim A As Range
Set A = sht2.[D:D].Find(TextBox3.Text, lookat:=xlWhole)
'如果查無員工編號，要求重新輸入員工編號
If A Is Nothing Then '如果編號不存在
MsgBox "查無員工編號，請重新輸入"
UserForm1.TextBox3.Text = ""
UserForm1.TextBox3.SetFocus
Exit Sub
End If
With sht1
.Range("B7") = A.Offset(, 1)
End With
End Sub

複製代碼

作者: man65boy 時間: 2012-1-9 23:13

回復 6# Hsieh

感謝超級版主的解題，小弟感恩在心頭，祝版主"龍年行大運~發大財" 新年快樂!

作者: GBKEE 時間: 2012-1-10 08:17

回復 5# man65boy

Dim sht1 As Worksheet, sht2 As Worksheet
Private Sub CommandButton1_Click()
Dim ranme As Variant
'輸入員工編號後用 Match 函數來取得員工姓名
ranme = Application.Match(TextBox3.Text, sht2.Range("D:D"), 0)
'如果查無員工編號，要求重新輸入員工編號
With sht1
If IsError(ranme) Then '如找到 ranme->傳回數字 ,否則 ranme ->錯誤值 "# N/A"
MsgBox "查無員工編號，請重新輸入"
UserForm1.TextBox3.Text = ""
UserForm1.TextBox3.SetFocus
.Range("B7") = ""
Else
.Range("B7") = sht2.Range("E" & ranme)
End If
End With
End Sub
Private Sub CommandButton2_Click()
Unload Me
End Sub
Private Sub UserForm_Initialize()
Set sht1 = Sheets("列印")
Set sht2 = Sheets("資料表")
End Sub

複製代碼

作者: man65boy 時間: 2012-1-10 19:26

回復 8# GBKEE

感謝GBKEE大大的解題，讓小弟又多了不一樣程式碼參考學習，感謝你，也祝你"龍年行大運~財源滾來" 新年快樂!

歡迎光臨麻辣家族討論版版 (http://forum.twbts.com/)