標題: [發問] 如何讓5位數的時間格式能正常相減 [打印本頁]

---

作者: zxcv778899    時間: 2020-3-24 14:40     標題: 如何讓5位數的時間格式能正常相減

本帖最後由 zxcv778899 於 2020-3-24 14:47 編輯

當計算的時數過萬小時時，會出現錯誤
設定：A1、B1、C1儲存格格式為小時:分鐘 [h]:mm
A1輸入：10000:01
B1輸入：12000:00
C1輸入公式=B:B-A:A
正確應顯示1999:59，但會出現#VALUE!
該格式計算4位數以下皆正常
網路爬文儲存格相關設定教學 尚未找到能解決的設定
煩請高手求解

---

作者: cucu    時間: 2020-3-24 15:39

回復 1# zxcv778899


    https://support.office.com/zh-tw/article/excel-%E7%9A%84%E8%A6%8F%E6%A0%BC%E5%8F%8A%E9%99%90%E5%88%B6-1672b34d-7043-467e-8e27-269d656771c3

可以輸入的最大時間值  9999:59:59

---

作者: c_c_lai    時間: 2020-3-25 06:11

回復 1# zxcv778899
請參考：
Excel-整理自編Excel教學文章集(~2015/5/24)
https://isvincent.pixnet.net/blog/post/44882566

---

作者: zxcv778899    時間: 2020-3-25 10:44

本帖最後由 zxcv778899 於 2020-3-25 10:54 編輯

謝謝 cucu跟c_clai兩位大大提供相關資料

因Excel有可輸入最大時間值  9999:59:59 的限制(無法顯示5位數)

故解決方式將小時:分鐘改為分鐘計算後再轉回原資料格式
設定：求時間二減時間ㄧ的值。第一列為標題。A2、E2儲存格格式設定為文字(因為Excel預設的自定義，會變其他日期格式)
時間一A2輸入7777:10
時間一的小時B2輸入=LEFT(A2,SEARCH(":",A2,1)-1)
時間一的分鐘C2輸入=RIGHT(A2,LEN(A2)-SEARCH(":",A2,1))
時間一的總分鐘D2輸入=(B2*60)+C2

時間二E2輸入17777:20
時間二的小時F2輸入=LEFT(E2,SEARCH(":",E2,1)-1)
時間二的分鐘G2輸入=RIGHT(E2,LEN(E2)-SEARCH(":",E2,1))
時間二的總分鐘H2輸入=(F2*60)+G2

相減時間I2輸入=TEXT(INT((H2-D2)/60),"00")&":"&TEXT(MOD((H2-D2),60),"00")
計算結果10000:10
(4位數跟5位數都能計算)

以上小弟分很了多步驟解出來了^_^
如果有高手可以簡化歡迎提供 感恩

---

作者: 准提部林    時間: 2020-3-25 12:50

回復 4# zxcv778899

時間一:A2輸入"7777:10"
時間二:B2輸入"17777:20"
C2/公式:
=TEXT(MMULT((SUBSTITUTE(A2:B2,":"," ")&"/60")/24,{-1;1}),"[h]:mm")

---

作者: zxcv778899    時間: 2020-3-25 16:57

回復 5# 准提部林

謝謝版主解答 感恩

---

歡迎光臨 麻辣家族討論版版 (http://forum.twbts.com/)