標題:
如何在指定時間自動存檔及關閉EXCEL
[打印本頁]
作者:
cdkee
時間:
2010-10-20 17:15
標題:
如何在指定時間自動存檔及關閉EXCEL
請教大大,要在下午3時10分自動存檔及關閉EXCEL,應該怎樣寫,謝謝大大!
作者:
GBKEE
時間:
2010-10-20 20:19
回復
1#
cdkee
http://forum.twbts.com/viewthread.php?tid=1657&extra=&page=1
Sub Ex()
Application.OnTime "15:10", "AUTO_CLOSE"
End Sub
Sub AUTO_CLOSE()
ThisWorkbook.Save
Application.Quit
End Sub
複製代碼
作者:
cdkee
時間:
2010-10-20 22:36
回復
2#
GBKEE
謝謝版大指導!
如果在隱藏工具列時,應怎樣改寫,再謝謝版大教授!
[attach]3300[/attach]
作者:
cdkee
時間:
2010-10-20 23:49
回復
2#
GBKEE
謝謝版大循循善誘,小輩初次完成功課,請版大檢測,謝謝!
[attach]3302[/attach]
作者:
GBKEE
時間:
2010-10-21 08:27
回復
4#
cdkee
二選一
ThisWorkbook的程式碼
Private Sub Workbook_Open()
MsgBox "開啟 Sub Workbook_Open 程式"
With Application
'隱藏 Ribbon(功能區)
.ExecuteExcel4Macro "SHOW.TOOLBAR(""Ribbon"",False)"
.StatusBar = False
.CommandBars("Status Bar").Visible = False
.StatusBar = True 'False
.DisplayFormulaBar = False
.DisplayScrollBars = False
.Caption = "It's all gone!"
.ActiveWindow.DisplayHeadings = False
.ActiveWindow.DisplayWorkbookTabs = False
'將視窗狀態設為一般
.WindowState = xlNormal
.Width = 250
.Height = 250
End With
Application.OnTime "08:22:56", "ThisWorkbook.EX"
End Sub
Private Sub Workbook_BeforeClose(Cancel As Boolean)
With Application
'隱藏 Ribbon(功能區)
.ExecuteExcel4Macro "SHOW.TOOLBAR(""Ribbon"",True)"
.CommandBars("Status Bar").Visible = True
.DisplayFormulaBar = True
.DisplayScrollBars = True
.Caption = "It's all gone!"
.ActiveWindow.DisplayHeadings = True
.ActiveWindow.DisplayWorkbookTabs = True
'將視窗狀態設為一般
.WindowState = xlMaximized
End With
Application.Quit
End Sub
Private Sub EX()
ThisWorkbook.Close 1
End Sub
複製代碼
Module的程式碼
Sub AUTO_OPEN()
With Application
'隱藏 Ribbon(功能區)
.ExecuteExcel4Macro "SHOW.TOOLBAR(""Ribbon"",False)"
.StatusBar = False
.CommandBars("Status Bar").Visible = False
.StatusBar = True 'False
.DisplayFormulaBar = False
.DisplayScrollBars = False
.Caption = "It's all gone!"
.ActiveWindow.DisplayHeadings = False
.ActiveWindow.DisplayWorkbookTabs = False
'將視窗狀態設為一般
.WindowState = xlNormal
.Width = 250
.Height = 250
End With
Application.OnTime "23:36", "AUTO_CLOSE"
End Sub
Sub AUTO_CLOSE()
With Application
'隱藏 Ribbon(功能區)
.ExecuteExcel4Macro "SHOW.TOOLBAR(""Ribbon"",True)"
.CommandBars("Status Bar").Visible = True
.DisplayFormulaBar = True
.DisplayScrollBars = True
.Caption = "It's all gone!"
.ActiveWindow.DisplayHeadings = True
.ActiveWindow.DisplayWorkbookTabs = True
'將視窗狀態設為一般
.WindowState = xlMaximized
End With
ThisWorkbook.Save
Application.Quit
End Sub
複製代碼
作者:
cdkee
時間:
2010-10-21 17:30
回復
5#
GBKEE
謝謝 版大的多方教導,小輩深被感動!
請教版大:
ThisWorkbook的程式碼中...
問1) Application.OnTime "08:22:56",
"ThisWorkbook.EX"
<---是因為Private Sub EX() 在ThisWorkbook中?
問2) Private Sub EX() <---在這個例子用Private有沒有特別意思?
問3) Private Sub Workbook_BeforeClose(Cancel As Boolean)與Private Sub Workbook_BeforeClose()有什麼分別?
問4) ThisWorkbook.Save <---是否漏寫這個?
問5) ThisWorkbook.Close 1是否指關閉檔案而不關閉EXCEL?'Close'之後的數字有什麼意思?
Module的程式碼中...
問6) Sub AUTO_OPEN()...不用Private Sub Workbook_Open()是因為在Module的程式不可用Private?或有其他因素?
問7) 小輩仍然分不清,何時用Sheet/ThisWorkbook,何時用Module?
小輩問題多多,煩請版大引導,謝謝!
作者:
GBKEE
時間:
2010-10-21 20:34
回復
6#
cdkee
問1) 沒錯 Application.OnTime "08:22:56", "ThisWorkbook.EX"
程序在 ThisWorkbook,Sheet1,Sheet2 ....等
物件
模組
需指明
, 程序在
一般
模組(Module)內則
不需指明
程序所在的模組.
問2) Private Sub EX() <---在這個例子用Private有沒有特別意思?
Sub EX() => Public Sub EX(),是公用的其他
物件
模組或
一般
模組(Module)都可以使用的.
Private Sub EX() 是私用的,其他
物件
模組或
一般
模組(Module) 無法使用.
例如有Private Sub EX() 及 Sub Example() 兩程序 在指令 [工具]->[巨集] 只可以找到Sub Example()
問3) Private Sub Workbook_BeforeClose(Cancel As Boolean)與Private Sub Workbook_BeforeClose()有什麼分別?
Private Sub Workbook_BeforeClose(Cancel As Boolean) 是於
關閉Workbook時的內建觸動事件
Private Sub Workbook_BeforeClose()因與上述內建觸動事件名稱相同,如在ThisWorkbook
物件
模組內是不允許的.
問4) ThisWorkbook.Save <---是否漏寫這個? 看不明白你的意思
問5) ThisWorkbook.Close 1 正式寫法 ThisWorkbook.
Close
SaveChanges:=True (VBA False=0, True=1)
問6) Sub AUTO_OPEN()...不用Private Sub Workbook_Open()是因為在Module的程式不可用Private?或有其他因素?
Private Sub Workbook_Open() 是
Workbook開啟時的內建觸動事件
,放於Module的程式碼中,不會於檔案開檔時自動執行.
問7) 小輩仍然分不清,何時用Sheet/ThisWorkbook,何時用Module?
多多練習後會融會貫通的!!
作者:
cdkee
時間:
2010-10-21 23:38
回復
7#
GBKEE
先謝謝版大詳細講解,小輩在學習中。
作者:
apolloooo
時間:
2011-1-14 22:54
我也有學到一些手法了。
xxx.show 0 或 1 ,也是一樣的意思。
歡迎光臨 麻辣家族討論版版 (http://forum.twbts.com/)