標題: [發問] 函數_將相互對應的二個【比對連續期數】改為二個【比對區域】。 [打印本頁]

---

作者: Airman    時間: 2015-12-9 09:47     標題: 函數_將相互對應的二個【比對連續期數】改為二個【比對區域】。

本帖最後由 Airman 於 2015-12-9 09:50 編輯

[attach]22763[/attach]
T7
=IF(L_1,"",IF(MODE(N(OFFSET($I$6,CHOOSE({1;2},T$5-1,$R7-1),{1,2,3,4,5,6,7})),0,0)*MODE(N(OFFSET($I$6,CHOOSE({1;2},T$5-2,$R7-2),{1,2,3,4,5,6,7})),0,0)*MODE(N(OFFSET($I$6,CHOOSE({1;2},T$5-3,$R7-3),{1,2,3,4,5,6,7})),0,0),$R7-3,""))
即在T5-1(=90期),T5-2(=89期),T5-3(=88期)三個連續期數比對R7-1,R7-2,R7-3三個連續期數，其三個相互對應期數，都必須含有一個(含)以上的交集值。

需求︰
可否能將公式中的T5-1,T5-2,T5-3改為T5-1：T5-3(即視為A區域)表達?
另將公式中的R7-1,R7-2,R7-3改為R7-1︰R7-3(即視為B區域)表達?

說明︰
因為如果想將相互對應的二個比對連續期數，擴充到7期或擴充到10期，就必須寫7次或10次的公式，
所以希望能將相互對應的二個比對連續期數改為二個比對區域。
不知函數能否達成需求?

詳細說明及圖示如附件。

以上  懇請各位先進、前輩不吝賜教!  謝謝!

---

作者: 准提部林    時間: 2015-12-9 14:56

本帖最後由 准提部林 於 2015-12-9 14:58 編輯

=IF(L_1,"",IF(AND(MMULT(1-ISNA(RANK(N(OFFSET($I$6,T$5-{1;2;3},{1,2,3,4,5,6,7})),OFFSET($I$6,$R7-{1;2;3},1,,7))),ROW($1:$7)^0)),$R7-3,""))

=IF(L_1,"",IF(AND(MMULT(SUMIF(OFFSET($I$6,$R7-{1;2;3},1,,7),N(OFFSET($I$6,T$5-{1;2;3},{1,2,3,4,5,6,7}))),ROW($1:$7)^0)),$R7-3,""))

=IF(L_1,"",IF(AND(MMULT(COUNTIF(OFFSET($I$6,$R7-{1;2;3},1,,7),N(OFFSET($I$6,T$5-{1;2;3},{1,2,3,4,5,6,7}))),ROW($1:$7)^0)),$R7-3,""))


ROW($1:$7)^0 可用 {1;1;1;1;1;1;1}

---

作者: Airman    時間: 2015-12-9 15:26

回復 2# 准提部林
准大:
謝謝您再次熱心協助和指導!3個貴解公式測試OK~感恩

可否再請賜教~
將交集值的條件再進階為必須同欄位。
謝謝您

---

作者: 准提部林    時間: 2015-12-9 15:33

回復 3# Airman


怎樣的同欄？
列對列的同欄？

看不懂∼∼

---

作者: Airman    時間: 2015-12-9 16:26

回復 4# 准提部林
准大:
是的~限定列對列的同欄位之相同值。
敬請再次指導~感恩

[attach]22770[/attach]

---

作者: 准提部林    時間: 2015-12-9 16:34

回復 5# Airman

=IF(L_1,"",IF(AND(MMULT(N(OFFSET($I$6,T$5-3,1,3,7)=OFFSET($I$6,$R7-3,1,3,7)),{1;1;1;1;1;1;1})),$R7-3,""))

---

作者: Airman    時間: 2015-12-9 16:41

回復 6# 准提部林
准大:
全OK了~感謝您

---

歡迎光臨 麻辣家族討論版版 (http://forum.twbts.com/)