標題: 日期顯示問題 [打印本頁]

---

作者: shan0948    時間: 2015-12-4 15:43     標題: 日期顯示問題

請問各位先進，在 Sheet2 內有每個人的日期資料，每個人日期多少不一，因姓名並不在同一欄內，而是在某一列，要在 Sheet1 輸入姓名後顯示 Sheet2 同姓名的全部日期資料，試過多函數公式，仍無法正確的日期資料，且 某姓名 Sheet2 儲存格無日期資料卻會顯示1900/01/01，請問如何能顯示正確的資料，謝謝！[attach]22704[/attach]

---

作者: 准提部林    時間: 2015-12-4 18:24

每個人的日期資料是否固定２欄？

---

作者: shan0948    時間: 2015-12-4 19:33

回復 2# 准提部林

准大好，每個人的日期都只有二欄，謝謝！

---

作者: 准提部林    時間: 2015-12-4 20:20

Ａ４：下拉
=IF(ROW(A1)>COUNT(OFFSET(Sheet2!A$1,1,MATCH(A$3,Sheet2!$1:$1,)-1,99,2)),"",SMALL(OFFSET(Sheet2!A$1,1,MATCH(A$3,Sheet2!$1:$1,)-1,99,2),ROW(A1)))


或：
=LOOKUP("z",IF({1,0},"",TEXT(SMALL(OFFSET(Sheet2!A$1,1,MATCH(A$3,Sheet2!$1:$1,)-1,99,2),ROW(A1)),"yyyy/mm/dd")))

注意：此公式取出的日期為〔文字格式〕


OFFSET(Sheet2!A$1,1,MATCH(A$3,Sheet2!$1:$1,)-1,99,2))　是假設日期資料最多９９列，可自行調整∼∼

---

作者: hcm19522    時間: 2015-12-4 20:45

Sheet1!B3=IFERROR(INDIRECT("Sheet2!"&TEXT(RIGHT(SMALL(IF((IF(Sheet2!$A1:$H1="",Sheet2!$B1:$I1,Sheet2!$A1:$H1)=$A3)*(Sheet2!$B2:$I8<>""),ROW($B2:$I8)*100+COLUMN($B2:$I8)*10001),COLUMN(A1)),4),"!R0C00"),),"")
診列 右拉 是否固定２欄

---

作者: hcm19522    時間: 2015-12-4 21:42

請教 "准大 "
例 A1=QQ   A2:A4=空白  A5=WW   A6:A9=空白
如何程式反白 按 F9 呈現 "QQ";"QQ";"QQ";"QQ;"WW";"WW";"WW";"WW";"WW"
程式試很多 無法呈現 感恩

---

作者: shan0948    時間: 2015-12-4 22:06

回復 4# 准提部林


    淮大好，指導公式經測試可使用，並將公式稍做修改，符合原日期左右兩欄顯示，謝謝！

---

作者: 准提部林    時間: 2015-12-4 22:15

本帖最後由 准提部林 於 2015-12-4 22:21 編輯

回復 6# hcm19522


=LOOKUP(ROW(1:9),IF(A1:A9<>"",ROW(1:9)),A1:A9)
=LOOKUP(ROW(1:9),ROW(1:9)/(A1:A9<>""),A1:A9)

{"QQ";"QQ";"QQ";"QQ";"WW";"WW";"WW";"WW";"WW"}

第一格不可空白~~

---

作者: shan0948    時間: 2015-12-4 22:31

回復 5# hcm19522


    H大好，每個人固定兩欄，是我沒有表達清楚，是仍要按 Sheet2 原每個人日期排列順序顯示，謝謝！

---

作者: hcm19522    時間: 2015-12-5 11:02

http://blog.xuite.net/hcm19522/twblog/362661570
本題無固定二欄 謝謝 "准大" 指導 請參考

---

作者: shan0948    時間: 2015-12-5 21:13

回復 10# hcm19522


    感謝 h 大的指導，不固定欄數可以因應未來的需求，謝謝！

---

歡迎光臨 麻辣家族討論版版 (http://forum.twbts.com/)