標題: [發問] 關於如何讓IF涵數內帶的"文字"不顯示 [打印本頁]

---

作者: starry1314    時間: 2015-5-16 10:48     標題: 關於如何讓IF涵數內帶的"文字"不顯示

請問是IF無法這樣使用嗎?

EX:
=F40&CHAR(10)&C40&"("&H40&")"

如果都儲存格都無數據 會顯示  ---> ()

=IF(F40&CHAR(10)&C40&"("&H40&")"="()","",F40&CHAR(10)&C40&"("&H40&")")   ---->>會顯示空白 <<是我要的

但如果儲存格是跨頁的話就沒有效果...原本無跨頁可顯示為空白,但跨頁就都一直顯示為 ---> ()

---

作者: ML089    時間: 2015-5-16 22:29

回復 1# starry1314


=IF(COUNTA(F40,C40,H40)=0,"",F40&CHAR(10)&C40&"("&H40&")")

---

作者: starry1314    時間: 2015-5-17 09:09

感謝版主！！！真是幫了大忙∼不然表格真是醜

---

作者: starry1314    時間: 2015-5-17 12:55

本帖最後由 starry1314 於 2015-5-17 13:00 編輯

回復 2# ML089

請問版主如果遇到這種狀況該如何解決呢？

目前跨頁可解決讓他顯示為空白  =IF(COUNTA(F40,C40,H40)=0,"",F40&CHAR(10)&C40&"("&H40&")")
但如果 F40.C40.H40儲存格為定義名稱出來的資料,就又回到一樣的狀況了！

---

作者: starry1314    時間: 2015-5-17 17:07

本帖最後由 starry1314 於 2015-5-17 17:13 編輯

回復 2# ML089
目前只能先以格式化條件,設為白色 視而不見.....

---

作者: ML089    時間: 2015-5-17 17:59

回復 4# starry1314


    應該是定義名稱的問題，不知你的名稱如何定義

---

作者: starry1314    時間: 2015-5-17 18:18

本帖最後由 starry1314 於 2015-5-17 18:23 編輯

回復 6# ML089

例子:
'標籤數據(早)'!$F:$F
'標籤數據(午)'!$C:$C
'標籤數據(晚)'!$H:$H

因會去刪除到儲存格所以用定義名稱(整欄),否則一刪除我參照的儲存格會全都跳#RFF

---

作者: starry1314    時間: 2015-5-17 19:58

回復 6# ML089
附上檔案.......

[attach]20962[/attach]

---

作者: ML089    時間: 2015-5-17 21:22

回復 8# starry1314

A2 =IF('標籤數據(早餐)'!J2&'標籤數據(早餐)'!K2&'標籤數據(早餐)'!L2="","",'標籤數據(早餐)'!J2&CHAR(10)&'標籤數據(早餐)'!K2&"("&'標籤數據(早餐)'!L2&")")

因為J K L為公式，雖然回傳""但對COUNTA函數視為有資料內容

---

作者: starry1314    時間: 2015-5-17 21:34

回復 9# ML089


    了解~那我只好先用格式化來做處理了！感謝

---

作者: ML089    時間: 2015-5-17 21:44

回復 10# starry1314

不用格式化，前面的公式我已經改好了，套用就可以。

另外我看你每欄的公式是跳19列，每欄都要修改很麻煩，下列公式只要你右拉複製公式時會自動跳19列
A2 =IF(COUNT(0/(T(OFFSET('標籤數據(早餐)'!$J2,COLUMN(A1)*19-19,{0,1,2}))=""))=3,"",OFFSET('標籤數據(早餐)'!$J2,COLUMN(A1)*19-19,)&CHAR(10)&OFFSET('標籤數據(早餐)'!$K2,COLUMN(A1)*19-19,)&"("&OFFSET('標籤數據(早餐)'!$L2,COLUMN(A1)*19-19,)&")")

右拉下拉複製公式

---

作者: starry1314    時間: 2015-5-17 22:39

回復 11# ML089

真的說到我的心聲了。。。今天就改了數百欄了。。。真是太感謝了！

---

歡迎光臨 麻辣家族討論版版 (http://forum.twbts.com/)