返回列表 上一主題 發帖

可否簡化 VBA 語法

可否簡化 VBA 語法

大家好,我寫一串語法
但自覺得過程太冗長,是否可以簡化程式語法


條件1.在A欄位,只要出現是"空白",就整列移除
條件2.在A欄位,只要出現這些英文,就整列移除 : TPD . TPD-both . TPD-viewing . GSA

Sub Step1()

On Error Resume Next
[A:A].SpecialCells(xlCellTypeBlanks).EntireRow.Delete
On Error GoTo 0
End Sub

Sub Step2()

Dim yy
yy = "TPD"
For I = [a65536].End(xlUp).Row To 1 Step -1
If WorksheetFunction.CountIf(Rows(I), yy) > 0 Then Rows(I).Delete
Next I
End Sub

Sub Step3()

Dim yy
yy = "TPD-both"
For I = [a65536].End(xlUp).Row To 1 Step -1
If WorksheetFunction.CountIf(Rows(I), yy) > 0 Then Rows(I).Delete
Next I
End Sub

Sub Step4()

Dim yy
yy = "TPD-viewing"
For I = [a65536].End(xlUp).Row To 1 Step -1
If WorksheetFunction.CountIf(Rows(I), yy) > 0 Then Rows(I).Delete
Next I
End Sub

Sub Step5()

Dim yy
yy = "GSA"
For I = [a65536].End(xlUp).Row To 1 Step -1
If WorksheetFunction.CountIf(Rows(I), yy) > 0 Then Rows(I).Delete
Next I
End Sub

在麻煩各位先進!
Just do it.

回復 1# jsc0518


Try this:
  1. Sub zz()
  2. Application.ScreenUpdating = 0
  3. Dim x(), rng As Range, ar, Myr&
  4. x = Array("TPD", "TPD-both", "TPD-viewing", "GSA")
  5. Myr = [a65536].End(3).Row
  6. ar = Range("a1:a" & Myr)
  7. Set rng = Cells(Myr + 1, 1)
  8. For i = 1 To UBound(ar)
  9.     If Len(ar(i, 1)) = 0 Then
  10.         Set rng = Union(rng, Cells(i, 1))
  11.     Else
  12.         For j = 0 To UBound(x)
  13.             If InStr(ar(i, 1), x(j)) Then Set rng = Union(rng, Cells(i, 1))
  14.         Next
  15.     Next
  16. Next
  17. rng.EntireRow.Delete
  18. Application.ScreenUpdating = 1
  19. End Sub
複製代碼
hth
ikboy

TOP

  1. Sub ex()
  2.     For i = Cells(Rows.Count, 1).End(xlUp).Row To 1 Step -1
  3.         For Each x In Array("", "TPD", "TPD-both", "TPD-viewing", "GSA")
  4.             If Cells(i, 1) = x Then Cells(i, 1).EntireRow.Delete
  5.         Next
  6.     Next
  7. End Sub
複製代碼
{...} 表示需要用 CTRL+SHIFT+ENTER 三鍵輸入公式

TOP

回復 2# ikboy

您好,感謝回覆,但在執行過程中會發生錯誤訊息,如下圖


有Next 沒有 For

001.jpg
2017-2-8 09:58


028-01.zip (11.74 KB)

在麻煩您了!
Just do it.

TOP

回復 3# ML089

ML089
感謝您的提供,測試成功,謝謝您!
Just do it.

TOP

本帖最後由 准提部林 於 2017-2-8 10:19 編輯

若只檢查A欄的內容,參考如下:
Sub zz2()
Dim T$, xR As Range, xE As Range
T = "_TPD_TPD-both_TPD-viewing_GSA_" '將索引值用"_"連接
Set xE = [A65536].End(xlUp)(2) '設A欄最後一格的下一格為 xE
For Each xR In Range([A1], xE(0))
  If xR = "" Or InStr(T, "_" & xR & "_") Then Set xE = Union(xE, xR)
Next
xE.EntireRow.Delete
End Sub

資料多的話,檢查完畢再一次刪,速度較快∼∼
EXCEL參考資料:
http://blog.xuite.net/smile1000mile/blog

TOP

回復 4# jsc0518


Sorry 沒測試, 己更正:
Sub zz()
Application.ScreenUpdating = 0
Dim x(), rng As Range, ar, Myr&
x = Array("TPD", "TPD-both", "TPD-viewing", "GSA")
Myr = [a65536].End(3).Row
ar = Range("a1:a" & Myr)
Set rng = Cells(Myr + 1, 1)
For i = 1 To UBound(ar)
    If Len(ar(i, 1)) = 0 Then
        Set rng = Union(rng, Cells(i, 1))
    Else
        For j = 0 To UBound(x)
            If InStr(ar(i, 1), x(j)) Then Set rng = Union(rng, Cells(i, 1))
        Next
    End if
Next
rng.EntireRow.Delete
Application.ScreenUpdating = 1
End Sub

TOP

回復 7# ikboy


您好,我有測試過,但仍有一些問題,若A欄是空白的(我要刪除列),但在H欄有資料(我不需要)
經測試後,它(H爛)的資料仍會存在,並不會因為A欄是空白而刪除整列
Just do it.

TOP

回復 3# ML089

您好,我有測試過,但仍有一些問題,若A欄是空白的(我要刪除列),但在H欄有資料(我不需要)
經測試後,它(H爛)的資料仍會存在,並不會因為A欄是空白而刪除整列
Just do it.

TOP

回復 6# 准提部林

您好,我有測試過,但仍有一些問題,若A欄是空白的(我要刪除列),但在H欄有資料(我不需要)
經測試後,它(H爛)的資料仍會存在,並不會因為A欄是空白而刪除整列
Just do it.

TOP

        靜思自在 : 有心就有福,有願就有力,自造福田,自得福緣。
返回列表 上一主題