返回列表 上一主題 發帖

averageifs 同一個欄位,不同值

averageifs 同一個欄位,不同值

大家午安,想請教個問題
我想統計平均值,所以用averageifs來計算

我想去計算星期一 ~ 二的平均值,所以我公式這樣寫

=AVERAGEIFS(M4:M33,B4:B33,"星期一",B4:B33,"星期二")

可卻不行,出現#div/0!

若拿掉星期二的部分,卻可以算出,是我的邏輯不對嗎??

data.png
2016-6-27 16:30

剛測試
  1. =AVERAGEIFS($M$4:$M$33,$B$4:$B$33,"<>星期一",$B$4:$B$33,"<>星期二",$B$4:$B$33,"<>星期三",$B$4:$B$33,"<>星期四")
複製代碼
可以算出五 ~ 日的平均,但為什麼用=卻不能呢???

TOP

本帖最後由 p212 於 2016-6-28 09:57 編輯

回復 1# owenchen0911
假設「日期」資料位於A欄,「星期」資料位於B欄,「杯數」資料位於C欄
1.製作動態範圍
(1)定義名稱「日期」,參照到輸入   =OFFSET(工作表1!$A$2,,,COUNT(工作表1!$A:$A))
(2)定義名稱「星期」,參照到輸入   =OFFSET(工作表1!$B$2,,,COUNT(工作表1!$A:$A))
(3)定義名稱「杯數」,參照到輸入   =OFFSET(工作表1!$C$2,,,COUNT(工作表1!$A:$A))

2.指定條件求平均值,如1#計算「星期一 ~ 二的平均值」:
=ROUND(SUMPRODUCT((星期={"星期一","星期二"})*杯數)/SUMPRODUCT((星期={"星期一","星期二"})*1),0)

請參考!

TOP

回復  owenchen0911
假設「日期」資料位於A欄,「星期」資料位於B欄,「杯數」資料位於C欄
1.製作動態範 ...
p212 發表於 2016-6-28 09:55




謝謝大大的幫忙,但可請問一下為什麼我的寫法不能呢??

再次謝謝

TOP

本帖最後由 KCC 於 2016-6-28 10:37 編輯

回復 4# owenchen0911


    你沒搞清楚函數的用法
#1
=AVERAGEIFS(M4:M33,B4:B33,"星期一",B4:B33,"星期二") 是求 同時是星期一也是星期二,所以當然是沒半個造成0除錯誤

給一個公式參考
=SUM(SUMIFS(M4:M33,B4:B33,{"星期一","星期二"}))/SUM(COUNTIFS(B4:B33,{"星期一","星期二"}))

#2

=AVERAGEIFS($M$4:$M$33,$B$4:$B$33,"<>星期一",$B$4:$B$33,"<>星期二",$B$4:$B$33,"<>星期三",$B$4:$B$33,"<>星期四")

求同時不等於星期一、星期二、星期三、星期四,所以會找出 星期五、星期六、星期天 的值求平均

-----------
給個建議,問問題能提供附檔加上適當的說明會好一些

TOP

回復  owenchen0911


    你沒搞清楚函數的用法
#1
=AVERAGEIFS(M4:M33,B4:B33,"星期一",B4:B33,"星 ...
KCC 發表於 2016-6-28 10:28




謝謝兩位大大的指點

TOP

        靜思自在 : 欣賞別人就是莊嚴自己。
返回列表 上一主題